XSLT空白命名空间

Question

我有XML我想要复制的是像（检查的xmlns =“”和标签。我想创建原样。

总的计算是照顾。只有这个问题。它是有效的。仍然客户希望预期的格式是这样的。任何帮助非常感谢。 三项任务

1）我需要添加命名空间员工xmnls =“1.2”xmlns：xsi =“3”xsi：schemalocation =“4 2）在输出xml中生成像这样的标签不是 3）需要避免xmlns =“”

任何帮助提前gr eatly赞赏 rameshkumar辛格

Input.xml中

<Employees> 
      <employee> 
      <dept>1</dept> 
       <sec></sec> 
      </employee> 
      <employee> 
       <dept>2</dept> 
       <sec></sec> 
      </employee> 
    </Employees> 

Expected.XML 

     <Employees xmnls="1.2" xmlns:xsi="3" xsi:schemalocation="4"> 
      <totalemp>2</totalemp> 
      <employee> 
       <dept>1</dept> 
       <sec></sec> 
      <employee> 
       <employee> 
        <dept>2</dept> 
        <sec></sec> 
       <employee> 
       </Employees> 


actual.XML 
       <Employees> 
        <totalemp>2</totalemp> 
         <employee xmlns=""> 
         <dept>1</dept> 
          <sec/> 
         </employee> 
         <employee> 
          <dept>2</dept> 
           <sec/> 
          <employee> 
       </Employees> 

Answer 1

这里是你如何做到这一点：

<xsl:stylesheet version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:xsi="3"> 

    <xsl:output indent="yes"/> 

    <xsl:template match="@* | node()"> 
     <xsl:copy> 
      <xsl:apply-templates select="@* | node()"/> 
     </xsl:copy> 
    </xsl:template> 

    <xsl:template match="*" priority="2"> 
     <xsl:element name="{local-name()}" namespace="1.2"> 
      <xsl:if test="self::Employees"> 
       <xsl:attribute name="xsi:schemalocation">4</xsl:attribute>   
      </xsl:if> 
      <xsl:apply-templates select="@* | node()"/> 
     </xsl:element> 
    </xsl:template> 
</xsl:stylesheet> 

您应用的身份转变为默认值，然后重写它的元素给他们提供了一个新的名称空间以及Employees节点的特殊属性。我选择添加if声明，但您也可以将该逻辑移入与Employees匹配的另一个模板。我只是不想重复整个xsl:element的事情两次。味道真的很重要。

当我将此转化为您的输入文档我结束了：

<Employees xmlns="1.2" xmlns:xsi="3" xsi:schemalocation="4"> 
    <employee> 
     <dept>1</dept> 
     <sec/> 
    </employee> 
    <employee> 
     <dept>2</dept> 
     <sec/> 
    </employee> 
</Employees> 

你必须在你的结果可能是xmlns=""因为你没有重新创建在新的命名空间的所有元素。此外，为了能够添加xsi:schemalocation属性，您需要在转换文档上声明xsi命名空间。

Answer 2

这种短期和简单的转换（有模板的最小数量，并且不使用任何明确的XSLT条件指令，没有xsl:attribute或priority属性）：当所提供的XML文档应用

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
xmlns:xsi="3" xsi:schemalocation="4"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:template match="node()[not(self::*)]|@*"> 
    <xsl:copy> 
    <xsl:apply-templates select="node()"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="*"> 
    <xsl:element name="{name()}" namespace="1.2"> 
    <xsl:copy-of select= 
    "document('')/*[not(current()/../..)] 
         /@xsi:schemalocation"/> 
    <xsl:apply-templates select="@*|node()"/> 
    </xsl:element> 
</xsl:template> 
</xsl:stylesheet> 

：

<Employees> 
    <employee> 
     <dept>1</dept> 
     <sec></sec> 
    </employee> 
    <employee> 
     <dept>2</dept> 
     <sec></sec> 
    </employee> 
</Employees> 

产生想要的，正确的结果：

<Employees xmlns="1.2" xmlns:xsi="3" xsi:schemalocation="4"> 
    <employee> 
     <dept>1</dept> 
     <sec/> 
    </employee> 
    <employee> 
     <dept>2</dept> 
     <sec/> 
    </employee> 
</Employees>