在Perl中，如何在括号中包含每个元素后连接数组的元素？

Question

我试图加入Perl数组的元素。

@array=('a','b','c','d','e'); 
$string=join(']',@array); 

会给我

$string="a]b]c]d]e"; 

反正我有可以迅速得到

$string="[a][b][c][d][e]"; 

？

Answer 1

另一种方式来做到这一点，利用sprintf。

my $str = sprintf '[%s]' x @array, @array; 

Answer 2

也许：

{ 
    local $" = "]["; 
    my @array = qw/a b c d e/; 
    print "[@array]"; 
} 

虽然你或许应该只是：

print "[" . join("][", @array) . "]"; 

快乐编码:-)

Answer 3

#!/usr/bin/perl 
use strict; use warnings; 

local $" = ''; 
my $x = qq|@{[ map "[$_]", qw(a b c d e) ]}|; 

您也可以概括一点：

#!/usr/bin/perl 
use strict; use warnings; 

my @array = 'a' .. 'e'; 

print decorate_join(make_decorator('[', ']'), \@array), "\n"; 

sub decorate_join { 
    my ($decorator, $array) = @_; 
    return join '' => map $decorator->($_), @$array; 
} 

sub make_decorator { 
    my ($left, $right) = @_; 
    return sub { sprintf "%s%s%s", $left, $_[0], $right }; 
} 

Answer 4

这里有两种选择：

#!/usr/bin/perl 

use strict; 
use warnings; 

my @array = 'a' .. 'e'; 
my $string = join('', map { "[$_]" } @array); 
my $string1 = '[' . join('][', @array) . ']';