Userform文本框是数字（和空值）

Question

我正在实现一个用户窗体，并希望在运行用户窗体之前在输入数据中包含一些检查。特别是，检查Userform文本框中的所有输入都是数字，尽管它是有效的，但文本框为空或为空。我试图执行以下操作：

Select Case KeyAscii 
    Case 0, 46, 48 To 57 
    Case Else 
    MsgBox "Only numbers allowed" 
    End Select 

但这不起作用。 请问，想法？ 非常感谢你!!!!!!!!!

Answer 1

也许有点冗长 - 我通常使用类模块和控件上的标签属性来决定可以在文本框中输入的内容。

用四个文本框创建一个表单。
给文本框，这些标签：

• 1; CDBL
• 2; CINT
• 3; CSTR
• 4; CSENTENCE

的数字是粘贴的列值保存到表单时（我没有在这里描述过）。
该文本描述了可以在文本框中输入的内容 - CDBL是2位小数的数字，CINT是数字，0位小数，CSTR用于正确文本，CSENTENCE用于文本文本。

创建一个名为clsControlText的课程模块。
该代码添加到类模块：

Public WithEvents txtBox As MSForms.TextBox 

Private Sub txtBox_Change() 
    Static LastText As String 
    Static SecondTime As Boolean 
    Const MaxDecimal As Integer = 2 
    Const MaxWhole As Integer = 1 

    With txtBox 
    If InStr(.Tag, ";") > 0 Then 
     Select Case Split(.Tag, ";")(1) 
      Case "CDBL", "CCur" 
       'Allow only numbers with <=2 decimal places 
       If Not SecondTime Then 
        If .Text Like "[!0-9.-]*" Or Val(.Text) < -1 Or _ 
         .Text Like "*.*.*" Or .Text Like "*." & String$(1 + MaxDecimal, "#") Or _ 
         .Text Like "?*[!0-9.]*" Then 
         Beep 
         SecondTime = True 
         .Text = LastText 
        Else 
         LastText = .Text 
        End If 
       End If 
       SecondTime = False 
      Case "CINT" 
       'Allow only whole numbers. 
       If .Text Like "[!0-9]" Or Val(.Text) < -1 Or .Text Like "?*[!0-9]*" Then 
        Beep 
        .Text = LastText 
       Else 
        LastText = .Text 
       End If 
      Case "CSTR" 
       'Convert text to proper case. 
       .Text = StrConv(.Text, vbProperCase) 
      Case "CSENTENCE" 
       'Convert text to sentence case (capital after full-stop). 
       .Text = ProperCaps(.Text) 
      Case Else 
       'Allow anything. 
     End Select 
    End If 
    End With 
End Sub 

Private Function ProperCaps(strIn As String) As String 
    Dim objRegex As Object 
    Dim objRegMC As Object 
    Dim objRegM As Object 
    Set objRegex = CreateObject("vbscript.regexp") 
    strIn = LCase$(strIn) 
    With objRegex 
     .Global = True 
     .ignoreCase = True 
     .Pattern = "(^|[\.\?\!\r\t]\s?)([a-z])" 
     If .Test(strIn) Then 
      Set objRegMC = .Execute(strIn) 
      For Each objRegM In objRegMC 
       Mid$(strIn, objRegM.firstindex + 1, objRegM.Length) = UCase$(objRegM) 
      Next 
     End If 
     ProperCaps = strIn 
    End With 
End Function 

将此代码添加到用户窗体：

Private colTextBoxes As Collection 

Private Sub UserForm_Initialize() 

    Dim ctrlSelect As clsControlText 
    Dim ctrl As Control 


    Me.Caption = ThisWorkbook.Name 

    Set colTextBoxes = New Collection 
    For Each ctrl In Me.Controls 
     Select Case TypeName(ctrl) 
      Case "TextBox" 
       Set ctrlSelect = New clsControlText 
       Set ctrlSelect.txtBox = ctrl 
       colTextBoxes.Add ctrlSelect 
     End Select 
    Next ctrl 

End Sub 

注：并非所有的代码都是我的。我发现了ProperCaps和本网站其他地方的CDBL代码 - 或者也许是MrExcel。

Answer 2

你可以使用一个基本LIKE或Regexp

Sub Test() 
Debug.Print StrCheck("") 
Debug.Print StrCheck("hello kitty") 
Debug.Print StrCheck("4156") 
End Sub 

功能

Function StrCheck(strIn As String) As String 
Dim objRegex As Object 
Set objRegex = CreateObject("vbscript.regexp") 
objRegex.Pattern = "\d+" 
'vaidate empty string 
If Len(Trim(strIn)) = 0 Then 
    StrCheck = True 
Else 
'validate whether non-empty string is numeric 
    StrCheck = objRegex.Test(strIn) 
End If 
End Function