如何使用gnuplot创建径向图？

Question

可能重复：
How to get a radial(polar) plot using gnu plot?

我想径向（极）地块使用gnuplot的（即圆坐标系（r，THETA）:!

这里我已经使用的值：

如何使用gnu-plot得到这样的情节？如果我拿正值，说3400,5300,4700等等......我必须能够以同样的情节将他们绘制成不会令人困惑的样子。是否有一个gnu-plot命令直接提到半径和theta而不是x和y坐标来获得这样一个径向图？

在此先感谢

Answer 1

可能重复：here

我能想到的是只有这样，才能使用

set ytics ("-1000" 1000, "-2000" 2000, "-3000" 3000, "-4000" 4000, "-5000" 5000, "-6000" 6000) 

所以不是this问题的答案都使用这个脚本（仅此时间没有评论）：

unset border 
set polar 
set angles degrees 

set style line 10 lt 1 lc 0 lw 0.3 

set grid polar 60 
set grid ls 10 

set xrange [-6000:6000] 
set yrange [-6000:6000] 

set xtics axis 
set ytics axis 

set xtics scale 0 
set xtics ("" 1000, "" 2000, "" 3000, "" 4000, "" 5000, "" 6000) 
set ytics ("-1000" 1000, "-2000" 2000, "-3000" 3000, "-4000" 4000, "-5000" 5000,  "-6000" 6000) 

set size square 

set key lmargin 

set_label(x, text) = sprintf("set label '%s' at (6500*cos(%f)), (6500*sin(%f))    center", text, x, x) 

eval set_label(0, "0") 
eval set_label(60, "60") 
eval set_label(120, "120") 
eval set_label(180, "180") 
eval set_label(240, "240") 
eval set_label(300, "300") 

set style line 11 lt 1 lw 2 pt 2 ps 2 

plot "-" u 1:(-1*$2) t "Max strain" w lp ls 11 
0 -3400 
60 -5300 
120 -4700 
180 -3800 
240 -4100 
300 -3100 
360 -3400 
e