Mathematica中用于制作数学书籍图形的简单编程技巧/技巧？

Question

我试过使用它。对于一些情节来说，这真的很好，但是当它制作一个三角形时，我发现它非常复杂。我想出了如何绘制三角形，但如何添加角度标记，那些曲线？

因为我是初学者，所以写书的时候，任何人都可以推荐我这是最好的方法来完成好看的图形，例如下图所示。哪些程序最适合使用。

感谢您的任何建议和建议。

Answer 1

一个优秀的，支持Wolfram的产品是Geometrica。这不是一个便宜的附加组件，价格为495美元，但它会产生像您的图表，比以原始形式制作 MMA Mathematica更容易。它基本上是Szabolcs方法在评论中的一个非常大的扩展 - 用来绘制内容的函数库。

Answer 2

编辑您也可以从Demonstrations项目中获得灵感。 These are the triangle-related demonstrations.快速浏览后，我认为您应该看到Jay Warendorff与几何相关的演示。他做了很多这些，他们使用一组结构化的几何相关函数，这些函数很可能可以重用。

---

这里是一个angleArc功能，让你开始。这只是你可以使用的帮助函数的一个小例子，还有很大的改进空间。

angleArc[Polygon[vertices_List, ___], r_, i_] := 
Module[{a, b, c, phi1, phi2}, 
    {a, b, c} = Take[RotateLeft[vertices, i-2], 3]; 
    {phi1, phi2} = Sort@N[{ArcTan @@ (a - b), ArcTan @@ (c - b)}]; 
    If[phi2 - phi1 > Pi, phi1 += 2 Pi]; 
    Circle[b, r, {phi2, phi1}] 
] 

poly = Polygon[{{0, 0}, {1, 2}, {2, 1}}]; 

Graphics[{EdgeForm[Thick], FaceForm[None], poly, 
    Table[angleArc[poly, .2, i], {i, Length[poly[[1]]]}]}] 

Manipulate[ 
With[{poly = Polygon[{a, b, c}]}, 
    Graphics[ 
    {EdgeForm[Thick], FaceForm[None], poly, 
    Table[angleArc[poly, .2, i], {i, Length[poly[[1]]]}]}, 
    PlotRange -> 2 {{-1, 1}, {-1, 1}}, Frame -> True 
    ] 
    ], 
{{a, {0, 0}}, Locator}, {{b, {1, 0}}, Locator}, {{c, {0, 1}}, Locator} 
] 

Answer 3

我喜欢数学了很多。但是几何绘图有更好的选择。

在这里，您有（用非常低的分辨率）Geometry Expressions做了5分钟素描：

几何表达式做了一些不错的平面几何计算，并可以在网上将结果导出为MMA。

Answer 4

这里做一个简单/基本途径的第一个：

Graphics[{ 

(* The dashed circle segment *) 
{ 
    Dashing[{.04, .01}], 
    Darker[Orange], 
    AbsoluteThickness[2], 
    Circle[{0, 0}, 1, {1, 2 \[Pi]}] 
}, 

(* The solid circle segment *) 
{ 
    Orange, 
    AbsoluteThickness[2], 
    Circle[{0, 0}, 1, {0, 1}] 
}, 

(* The radial lines and the small circle segment *) 
Line[{{0, 0}, {1, 0}}], 
Line[{{0, 0}, {Cos[1], Sin[1]}}], 
Circle[{0, 0}, .2, {0, 1}], 

(* Various text labels *) 
{ 
    Text[Style["\[Theta]", 24], .3 {Cos[.5], Sin[.5]}], 
    Text[Style["s", 24], 1.1 {Cos[.5], Sin[.5]}], 
    Text[Style["r", 24], {.5, -.1}] 
} 
}] 

以下是完全一样的事情，但在角度alpha包裹在Manipulate和参数 ：

Manipulate[ 
Graphics[{ 
    {Dashing[{.04, .01}], Darker[Orange], AbsoluteThickness[2], 
    Circle[{0, 0}, 1, {\[Alpha], 2 \[Pi]}]}, 
    {Orange, AbsoluteThickness[2], Circle[{0, 0}, 1, {0, \[Alpha]}]}, 
    Line[{{0, 0}, {1, 0}}], 
    Line[{{0, 0}, {Cos[\[Alpha]], Sin[\[Alpha]]}}], 
    Circle[{0, 0}, .2, {0, \[Alpha]}], 
    {Text[Style["\[Theta]", 
    24], .3 {Cos[\[Alpha]/2], Sin[\[Alpha]/2]}], 
    Text[Style["s", 24], 1.1 {Cos[\[Alpha]/2], Sin[\[Alpha]/2]}], 
    Text[Style["r", 24], {.5, -.1}]} 
}], 
{{\[Alpha], 1}, 0, 2 \[Pi]}] 

如果移动滑块，内容将会相应改变：

Answer 5

是，Mathematica的内置图形工具在地方有点古怪，并有一些恼人的遗漏。但是基础图形的范围很广，从好的方面来说，您只需要从数学工具中轻击几下，就可以纠正图形编辑器的一些缺陷。需要一个弧线？只需在下面进行计算并将其复制/粘贴即可。无法使用Adobe Illustrator来做到这一点！还有广泛的方程式和希腊字符。当没有别的东西需要处理时，它可能会有所帮助。

这里的第一个 - 这不是完全不能接受的... :)

Answer 6

演示是一款优秀且成本低（$ 50），图形（以及更多）封装在MMA，以书面形式大卫公园。 http://home.comcast.net/~djmpark/DrawGraphicsPage.html

它在我们的计算器工具包提到资源N.2 What is in your Mathematica tool bag?