如何删除默认名称空间并使用XSLT保留其余的名称空间？

Question

我有一个XML文件，它具有默认名称空间和空名称空间，这些名称空间需要被删除，同时保留名称空间的其余部分。

输入：

<prefix:request xmlns:prefix="urn1" xmlns:foo2="urn2" xmlns="urn1"> 
<element1 xmlns="">version1</element1> 
<element2 xsi:type="prefix:requestA" xmlns=""/> 
... 
</element1> 
</prefix:request> 

预期输出：用于去除命名空间将过滤掉所有名称空间，包括前缀

<prefix:request xmlns:prefix="urn1" xmlns:foo2="urn2"> 
<element1>version1</element1> 
<element2 xsi:type="prefix:requestA"/> 
... 
</element1> 
</prefix:request> 

XSLT样品。任何想法如何解决这个特殊情况？

Answer 1

这短短的转变应用：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:template match="*"> 
    <xsl:element name="{name()}" namespace="{namespace-uri()}"> 
     <xsl:copy-of select="@*|namespace::*[name()]"/> 
     <xsl:apply-templates select="node()"/> 
    </xsl:element> 
</xsl:template> 
</xsl:stylesheet> 

当所施加的（严重畸形和具有要被校正）提供类似于XML的输入：

<prefix:request xmlns:xsi="Undefined !!!" 
xmlns:prefix="urn1" xmlns:foo2="urn2" 
xmlns="urn1"> 
    <element1 xmlns="">version1</element1> 
    <element2 xsi:type="prefix:requestA" xmlns=""/> ... 
</prefix:request> 

产生想要的，正确的结果：

<prefix:request xmlns:prefix="urn1" xmlns:xsi="Undefined !!!" xmlns:foo2="urn2"> 
    <element1>version1</element1> 
    <element2 xsi:type="prefix:requestA"/> ... 
</prefix:request> 

Answer 2

那么您发布的代码片段甚至不是格式良好的XML，因此很难说明您想要实现什么，因为第二个结束</element1>没有任何相应的开始标记，并且前缀xsi已被使用但从未宣布。

但是假设你有

<prefix:request xmlns:prefix="urn1" xmlns:foo2="urn2" xmlns="urn1" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"> 
<element1 xmlns="">version1</element1> 
<element2 xsi:type="prefix:requestA" xmlns=""/> 

</prefix:request> 

那么样式表

<xsl:stylesheet 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    version="1.0"> 

    <xsl:template match="*"> 
    <xsl:element name="{name()}" namespace="{namespace-uri()}"> 
     <xsl:copy-of select="namespace::*[local-name()]"/> 
     <xsl:apply-templates select="@* | node()"/> 
    </xsl:element> 
    </xsl:template> 

    <xsl:template match="@* | text() | comment() | processing-instruction()"> 
    <xsl:copy/> 
    </xsl:template> 

</xsl:stylesheet> 

当撒克逊6.5.5将输出

<?xml version="1.0" encoding="utf-8"?><prefix:request xmlns:prefix="urn1" xmlns:foo2="urn2" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"> 
<element1>version1</element1> 
<element2 xsi:type="prefix:requestA"/> 

</prefix:request>