转换功能，putStrLn'd返回字符串

Question

在standalone working script，我有一个函数返回IO()这样：

main :: IO() 
main = do 
    response <- simpleHttp "https://leonstafford.github.io" 

    let body = decodeUtf8 (response) 
    let bodyAsString = unpack (body) 

    putStrLn $ htmlToPlainText bodyAsString 

现在我试图利用同样的功能在this existing script，但与普通Couldn't match type ‘[Char]’ with ‘Char’挣扎：

renderPage :: String -> String 
renderPage url = do 
    response <- simpleHttp url 

    let body = decodeUtf8 (response) 
     bodyAsString = unpack (body) 
     articleAsPlainText = htmlToPlainText bodyAsString 
    return articleAsPlainText 

我一直在摆弄它和关闭了大约一个星期，希望我已经能够在标题足够的定义问题，所以它可能不是另一个can't match expected types后，虽然上午PRET肯定就是这样。

Answer 1

关于Haskell的好处是你可以一步一步做到这一点，大多数人并不担心你会得到完全不同的行为。首先，我们移动的main内容到一个新的功能：

renderPage :: IO() 
renderPage = do 
    response <- simpleHttp "https://leonstafford.github.io" 

    let body = decodeUtf8 (response) 
    let bodyAsString = unpack (body) 

    putStrLn $ htmlToPlainText bodyAsString 


main :: IO() 
main = renderPage 

接下来，我们添加url作为参数：

renderPage :: String -> IO() 
renderPage url = do 
    response <- simpleHttp url 

    let body = decodeUtf8 (response) 
    let bodyAsString = unpack (body) 

    putStrLn $ htmlToPlainText bodyAsString 

main :: IO() 
main = renderPage "https://leonstafford.github.io" 

最后，但并非最不重要的，我们移动putStrLn为main在renderPage使用return：

renderPage :: String -> IO String 
renderPage url = do 
    response <- simpleHttp url 

    let body = decodeUtf8 (response) 
    let bodyAsString = unpack (body) 

    return $ htmlToPlainText bodyAsString 

main :: IO() 
main = renderPage "https://leonstafford.github.io" >>= putStrLn 

这些步骤（迁入新功能，添加AR意见，移动功能）都非常小。所以当你遇到这样的问题时，不要害怕做一些中间步骤。

请注意，IO始终保持renderPage，因为simpleHttp使用IO。一旦你在某个函数中有某处，就无法摆脱IO。但renderPage的功能可以被重新使用，因为

renderPage :: String -> IO String 
renderPage = fmap (htmlToPlainText . unpack . decodeUtf8) . simpleHttp 

，因此：

utf8ToPlainText :: ByteString -> String 
utf8ToPlainText = htmlToPlainText . unpack . decodeUtf8 

renderPage :: String -> IO String 
renderPage = fmap utf8ToPlainText . simpleHttp