Oracle - 审计跟踪生成器？

我正在寻找将为Oracle数据库生成审计跟踪的通用过程。我们目前正在SQL Server上使用类似的过程，并想知道是否存在Oracle等价物。我们希望审计表将与原始表格分开，并包含用户/日期时间信息。Oracle - 审计跟踪生成器？

这是我们使用SQL Server相当于：https://www.codeproject.com/Articles/21068/Audit-Trail-Generator-for-Microsoft-SQL

任何意见是极大的赞赏。

来源

2017-10-09 AAA

您是否尝试过Oracle的本机审计？ https://docs.oracle.com/database/121/DBSEG/auditing.htm –

Hi @MartinBerger，由于担心性能/空间问题，DBA不想打开Oracle审核。理想情况下，我们会使用数据库触发器进行行级审计。谢谢 – AAA

我非常怀疑，任何本土审计将使用较少的空间，然后内置审计。 –

如果你不想使用Oracle本地机制，你可以有你自己的框架来生成和读取你自己的审计表（我知道你可以，我们曾经有过类似的工作）。

以下是主要成分：

a_sqnc是你将在TrackTable使用跟踪行动的顺序列NO_ORD（即使有也是D_UPD柱与修改时间）的序列。

create sequence a_sqnc 
minvalue 1 
maxvalue 99999999 
start with 1 
increment by 1 
nocache;

TrackTable将以便跟踪来自不同表的变化具有TABLE_NAME柱。它还有一个PK_VALUE和ROW_VALUE，我们在那里存储更改的数据。下面是表创建有用的索引：

create table TrackTable (
    table_name VARCHAR2(50) not null, 
    action  VARCHAR2(240) not null, 
    no_ord  NUMBER(12) not null, 
    nature  VARCHAR2(3) not null, 
    pk_value VARCHAR2(4000), 
    row_value VARCHAR2(4000), 
    ori  VARCHAR2(250), 
    c_user  VARCHAR2(20), 
    d_upd  DATE 
); 

create index AP_D_UPD on TrackTable (D_UPD); 
create index AP_NO_ORD on TrackTable (NO_ORD); 
create index AP_TABLE_NAME on TrackTable (TABLE_NAME);

假设你有一个简单的表BANK两列PK_val（主键）和val：

create table BANK (
    pk_val VARCHAR2(50) not null, 
    val VARCHAR2(240) not null 
); 

alter table BANK 
    add constraint BK_PK primary key (pk_val) 
    using index ;

使用DBMS_APPLICATION_INFO.READ_MODULE(w_sess_mod, w_sess_act)知道哪些模块和动作的作用：我将ORI列中的TrackTable连接在一起;
user Oracle会话变量将允许您跟踪谁在列c_user列做了更改;
以下是如何创建触发器TRCK_BNK以跟踪表BANK中的更改;它将分为3个动作：DELETE,UPDATE, INSERT（如果需要，您可以删除INSERT的情况）。

CREATE OR REPLACE TRIGGER "TRCK_BNK" 
AFTER DELETE OR INSERT OR UPDATE 
    ON BANK 
REFERENCING NEW AS NEW OLD AS OLD 
FOR EACH ROW 

DECLARE 
    w_a  VARCHAR2(10); 
    W_ERRM  VARCHAR2(1000); 
    W_CODE  VARCHAR2(1000); 
    w_n  VARCHAR2(200) := 'BANK'; 
    w_id  NUMBER := a_sqnc.nextval; 
    w_act  v$session.action%type; 
    w_mod  v$session.module%type; 
    w_ori  TrackTable.ORI%TYPE;  
BEGIN 
    DBMS_APPLICATION_INFO.READ_MODULE(w_mod, w_act); 
    w_ori := 'Module : '||w_mod ||' ; Action : '||w_act; 
    ---------------------------------- 
    -- test which action is for change 
    ---------------------------------- 
    IF UPDATING 
    THEN 
    w_a := 'UPDATE'; 
    ELSIF DELETING 
    THEN 
    w_a := 'DELETE'; 
    ELSIF INSERTING 
    THEN 
    w_a := 'INSERT'; 
    END IF; 
    ---------------------------------- 
    -- Insert into TrackTable 
    ---------------------------------- 
If w_a in ('UPDATE', 'DELETE') then 
    Insert into TrackTable 
     Select w_n, w_a, w_id, 'OLD', :OLD.pk_val, :OLD.val 
      , w_ori, user, sysdate 
     From Dual; 
End if; 

-- if you update, there is a new value and an old value 
If w_a in ('UPDATE', 'INSERT') then 
    Insert into TrackTable 
     Select w_n, w_a, w_id, 'NEW', :NEW.pk_val, :NEW.val 
      , w_ori, user, sysdate 
     From Dual; 
End if; 

Exception 
When others then 
    Begin 
    W_ERRM := SQLERRM; 
    W_CODE := SQLCODE; 
    -- try inserting in case of error anyway 
    Insert into TrackTable 
     Select w_n, w_a, -1, 'ERR', 'Grrr: '||W_CODE, W_ERRM 
       , w_ori, user, sysdate 
    From Dual; 
    End; 
End; 
/

然后添加功能，您的框架，产生触发器给定一个表，检索的变化，恢复表给定日期...

注意： 如果表格变化很大，这种跟踪表格中每个变化的方法都会影响性能。但对于几乎不会改变的参数表而言，这非常棒。

来源

2017-10-15 19:15:49

看看基于UNDO数据的Oracles Flashback Data Archive。它可以配置为跟踪对数据的任何更改。从11g2（11.2.0.4）开始，它可以在任何版本的Oracle中使用。在Oracle documentation它说优化是有限的，但基本功能是可用的任何版本。

来源

2017-10-17 13:06:50 Benjamin

Oracle - 审计跟踪生成器？

回答

相关问题