如何形成相同值和键

Question

1. 在常规的组，我有maps.Each地图的列表中包含3个键与 各自的值，如：

   def group= [] as DataList 
   def groupRequiredMap = ["a": Metadata.groupName, 
            "b": Metadata.instance, 
            "c": Metadata.color] 
       group << groupRequiredMap 
   

   组的输出被作为如下::

   [[a:apple, b:0, c:red], 
   [a:apple, b:0, c:green], 
   [a:apple, b:0, c:blue], 
   [a:apple, b:1, c:brown], 
   [a:apple, b:1, c:violet], 
   [a:grapes, b:0, c:black], 
   [a:grapes, b:0, c:yellow], 
   [a:grapes, b:1, c:orange], 
   [a:grapes, b:1, c:pink]] 
   

欲形成一组与b = 0，一组用b = 1苹果苹果的，一组用b = 0葡萄和一组克用b强奸= 1等等。笔者想输出是这样的：

[[a:apple, b:0, c:[red, green, blue]], 
[a:apple, b:1, c:[brown,violet]], 
[a:grapes, b:0, c:[black,yellow]], 
[a:grapes, b:1, c:[orange,pink]] 

Answer 1

在这里你去：

List list = [[a:'apple', b:0, c:'red'], [a:'apple', b:0, c:'green'], [a:'apple', b:0, c:'blue'], [a:'apple', b:1, c:'brown'], [a:'apple', b:1, c:'violet'], [a:'grapes', b:0, c:'black'], [a:'grapes', b:0, c:'yellow'], [a:'grapes', b:1, c:'orange'], [a:'grapes', b:1, c:'pink']] 

List result = []  

list.groupBy ({it.a},{it.b}).each { a -> 
    a.value.each { b -> 
     result << [a: a.key, b: b.key, c: b.value.c] 
    } 
} 

result 

Answer 2

代替each和变异的列表，你可以这样做：

def list = [[a:'apple', b:0, c:'red'], 
       [a:'apple', b:0, c:'green'], 
       [a:'apple', b:0, c:'blue'], 
       [a:'apple', b:1, c:'brown'], 
       [a:'apple', b:1, c:'violet'], 
       [a:'grapes', b:0, c:'black'], 
       [a:'grapes', b:0, c:'yellow'], 
       [a:'grapes', b:1, c:'orange'], 
       [a:'grapes', b:1, c:'pink']] 

List result = list.groupBy({it.a}, {it.b}).collectMany { aValue, groupA -> 
    groupA.collect { bValue, values -> [a: aValue, b: bValue, c:values] } 
} 

Answer 3

groupBy是你想要的第一件事。因此，分组的关键是subMap("a","b") - 一张只包含原始地图的“a”和“b”键的键/值的地图。之后，通过传播运算符*.将“关键地图”与包含所有“c”的新地图组合在一起。

list.groupBy{ it.subMap("a","b") }.collect{ k, ms -> k + [c: ms*.c] }