我有一个有10个子目录的目录。这些文件都包含不同的.bak文件。我试图创建一个脚本来检查是否有X个文件存在,如果文件数量超过X,它将删除最旧的文件。换句话说,我需要20个.bak文件的迭代。当第21个出现时,我想让批处理文件删除最早的文件。 这可能吗? 如果是这样,我可以创建一个查看所有子目录的单个脚本吗? 在此先感谢。文件保留脚本
Q
文件保留脚本
0
A
回答
0
假定您要检查父目录中的文件数。也可以为每个子目录完成。
@echo off
setlocal
set "max_number_files=20"
set "parrent_dir=c:\whatever_you_need"
set "extension=.bak"
pushd "%parrent_dir%"
set "count=0"
setlocal enableDelayedExpansion
for /f "delims=" %%a in ('dir /s /b /a:-d /o:-d /t:c *%extension%') do (
set /a count=count+1
if 1!count! GTR 1!max_number_files! (
rem --- remove the echo to activate deletion
echo del /q /f "%%~a"
)
)
popd
endlocal
endlocal
1
包括两个选项。第一个将在每个文件夹下留下%maxFiles%
bak
文件。第二个(Vista或更高版本的操作系统需要为ROBOCOPY窗口来获取文件的排序列表)将离开%maxFiles%
总
@echo off
setlocal enableextensions disabledelayedexpansion
set "rootFolder=%cd%"
set "maxFiles=20"
rem Option 1 - Keep %maxFiles% inside each of the subfolders
for /d /r "%rootFolder%" %%z in (*) do for /f "skip=%maxFiles% delims=" %%a in (
'dir /tc /o-d /a-d /b "%%~fz\*.bak" 2^>nul'
) do echo del "%%~fz\%%~nxa"
echo ------------------------------
rem Option 2 - Keep %maxFiles% in total under all the subfolders
for /f "skip=%maxFiles% tokens=2,*" %%a in ('
robocopy "%rootFolder%" "%rootFolder%" *.bak /l /nocopy /is /s /njh /njs /ndl /nc /ns /ts
^| findstr /v /r /e /i /c:"%rootFolder:\=\\%\\[^\\]*"
^| sort /r
') do echo del "%%b"
del
命令只回显到控制台。如果输出是正确的,去掉echo
命令来删除文件
0
这将检查d:\base\folder
下的每个文件夹,如果有超过20个*.bak
文件它将删除最早的所以只有20 * .bak文件依然存在,每个文件夹。
在一些示例文件夹上测试它。
@echo off
for /d /r "d:\base\folder" %%a in (*) do (
pushd "%%a"
for /f "skip=20 delims=" %%b in ('dir /b /a-d /o:-d *.bak ') do del "%%b"
popd
)
相关问题
- 1. 保留文本
- 2. Linux脚本 - 扩展保留
- 3. 产品保留脚本PHP
- 4. FTP脚本保留后放
- 5. Bash脚本:保留一行本地文件与远程文件同步
- 6. 批处理脚本以查找多个文件,并保留
- 7. 简单重命名文件保留前缀的脚本
- 8. 脚本删除目录,但保留的文件
- 9. 脚本/命令合并3个文件保留最后的文件名
- 10. 需要使用脚本更改文件内容,但保留原始文件名
- 11. Shell脚本.zip压缩文件夹保留文件夹结构(Mac OS X)
- 12. 保留副本上的文件属性
- 13. 复制文件并保留副本
- 14. Gulp-rev-all保留旧版本文件
- 15. 将ajax留言本保存到文件
- 16. Liquibase脚本不会保留数据
- 17. 复制shell脚本并保留权限
- 18. EDITTEXT不保留文本
- 19. AutoCompleteBox不保留文本
- 20. 保留文本框的值
- 21. 保留文本框的值
- 22. 在文本框内保留文本
- 23. 替换文本添加文本,但保留文件名
- 24. 脚本异步标记是否保留脚本执行顺序?
- 25. 读取文件,删除文本字段,保留数字文件
- 26. Powershell删除文件并保留文本文件
- 27. 在回发事件后保留文本框文本
- 28. logrotate保留旧文件名
- 29. django不保留文件名
- 30. 卸载后保留文件
文件数量不应超过子目录中的数量还是所有文件的数量? – npocmaka 2014-08-29 07:34:58