如何在替换中使用变量作为修饰符

Question

有没有办法在替换中使用变量作为修饰符？

my $search = 'looking'; 
my $replace = '"find: $1 ="'; 
my $modifier = 'ee'; 

s/$search/$replace/$modifier; 

我需要使用散列数组进行批量搜索 - 用不同的修饰符进行替换。

Answer 1

嗯，如果我不得不这样做，我会做这样的：

use warnings; 
use strict; 
my @stuff = (
{ 
    search => "this", 
    replace => "that", 
    modifier => "g", 
}, 
{ 
    search => "ono", 
    replace => "wendy", 
    modifier => "i", 
} 
); 
$_ = "this ono boo this\n"; 
for my $h (@stuff) { 
    if ($h->{modifier} eq 'g') { 
     s/$h->{search}/$h->{replace}/g; 
    } elsif ($h->{modifier} eq 'i') { 
     s/$h->{search}/$h->{replace}/i; 
    } 
    # etc. 
} 
print; 

有你可能想我觉得这个用那么只有这么多不同的修饰符很简单。

你可以使用eval这个，但它非常混乱。

Answer 2

如果您戴上安全护目镜和零分服装，则可以使用eval。

如：

use strict; 
use warnings; 
sub mk_re { 
    my ($search, $replace, $modifier) = @_; 
    $modifier ||= ''; 
    die "Bad modifier $modifier" unless $modifier =~ /^[msixge]*$/; 
    my $sub = eval "sub { s/($search)/$replace/$modifier; }"; 
    die "Error making regex for [$search][$replace][$modifier]: $@" unless $sub; 
    return $sub; 
} 

my $search = 'looking'; 
my $replace = '"find: $1 ="'; 
my $modifier = 'e'; 

# Sub can be stored in an array or hash 
my $sub = mk_re($search, $replace, $modifier); 

$_ = "abc-looking-def"; 
print "$_\n"; 
$sub->(); 
print "$_\n"; 

Answer 3

在使用eval编译新的替代方法可能是最简单的，你可以创建一个取代为更加模块化：

use warnings; 
use strict; 

sub subst { 
    my ($search, $replace, $mod) = @_; 

    if (my $eval = $mod =~ s/e//g) { 
     $replace = qq{'$replace'}; 
     $replace = "eval($replace)" for 1 .. $eval; 
    } else { 
     $replace = qq{"$replace"}; 
    } 
    sub {s/(?$mod)$search/$replace/ee} 
} 

my $sub = subst '(abc)', 'uc $1', 'ise'; 

local $_ = "my Abc string"; 

$sub->(); 

print "$_\n"; # prints "my ABC string" 

这只是轻轻测试，它留作练习为读者执行其他标志，如g

Answer 4

当然s/$search/$replace/按照您的预期工作。这是动态修饰符，不直截了当。

对于常规匹配modifierspimsx，您可以使用Perl的Extended Patterns作为模式的一部分即时修改修饰符标志。这些格式为(?pimsx-imsx)可打开/关闭这些修改器。

对于s//e和ee表单，您可以使用(?{ perl code})记录在同一个perlre部分。对于所有evale或ee表单，请考虑结果代码的安全性！

没有任何形式可以修改我知道的全局匹配，所以全局匹配和第一次匹配需要单独的语句。

Answer 5

下面是Kinopiko的答案和评估的组合。

eval在此用于以受控和可维护的方式生成查找表，并且使用查找表来保存所有不太乐于查看的if ... elsif .. elsif。

（非常轻度测试）

my @stuff = (
{ 
    search => "this", 
    replace => "that", 
    modifier => "g", 
}, 
{ 
    search => "ono", 
    replace => "wendy", 
    modifier => "i", 
} 
); 
$_ = "this ono boo this\n"; 

my @modifiers = qw{m s i x g e}; 

my $s_lookup = {}; 

foreach my $modifier (@modifiers) { 
    $s_lookup->{$modifier} = eval " sub { s/\$_[0]/\$_[1]/$modifier } "; 
} 

for my $h (@stuff) { 
    $s_lookup->{$h->{modifier}}->($h->{search},$h->{replace}); 
} 

print; 

为了这需要充分有用：可能改性剂

1. 组合
查找表
2. 排序功能，以便 'MSI' 组合与“错'组合将会走向同一个关键。