以编程方式配置SQL Server TCP设置

我们每当为客户安装SQL Server 2008 R2时都会执行手动过程。我们为实例启用TCP/IP和Named Pipes协议，将TCP Dynamic Ports设置为0，并将TCP Port设置为非标准端口号（为安全起见故意禁用浏览器）。连接总是使用明确的端口号（I.E. 192.168.1.100, 12345）以编程方式配置SQL Server TCP设置

如何从Delphi中以编程方式配置这些服务器TCP设置？

来源

2014-01-29 Jerry Dodge

实际上，答案是：根据您的SQL服务器版本更改注册表中的端口号，然后重新启动服务... – whosrdaddy

由于此问题收到了很好的备选答案，因此删除了近距离投票。 – whosrdaddy

您可以使用ServerNetworkProtocol WMI类，它是WMI Provider for Configuration Management Classes的一部分。

要访问此类，您必须连接到适当的名称空间，具体取决于您的SQL Server版本。

SQL Server 2005 - ComputerManagement 
SQL Server 2008 - ComputerManagement10 
SQL Server 2012 - ComputerManagement11

试试这个样本的SQL Server 2008

{$APPTYPE CONSOLE} 

uses 
    SysUtils, 
    ActiveX, 
    ComObj, 
    Variants; 


procedure EnableSQLServerNetworkProtocol(Const Protocol : string; EnableProtocol: Boolean); 
const 
    WbemUser   =''; 
    WbemPassword  =''; 
    WbemComputer  ='localhost'; 
    wbemFlagForwardOnly = $00000020; 
var 
    FSWbemLocator : OLEVariant; 
    FWMIService : OLEVariant; 
    FWbemObjectSet: OLEVariant; 
    FWbemObject : OLEVariant; 
    oEnum   : IEnumvariant; 
    iValue  : LongWord; 
begin; 
    FSWbemLocator := CreateOleObject('WbemScripting.SWbemLocator'); 
    FWMIService := FSWbemLocator.ConnectServer(WbemComputer, 'root\Microsoft\SqlServer\ComputerManagement10', WbemUser, WbemPassword); 
    FWbemObjectSet:= FWMIService.ExecQuery(Format('SELECT * FROM ServerNetworkProtocol Where ProtocolName="%s"', [Protocol]),'WQL',wbemFlagForwardOnly); 
    oEnum   := IUnknown(FWbemObjectSet._NewEnum) as IEnumVariant; 
    if oEnum.Next(1, FWbemObject, iValue) = 0 then 
    //if FWbemObject.Enabled<>EnableProtocol then 
     Writeln('Result '+VarToStr(FWbemObject.SetEnable(EnableProtocol))); // 0 means OK 
end; 


begin 
try 
    CoInitialize(nil); 
    try 
     EnableSQLServerNetworkProtocol('Tcp', True);// TCP/IP 
     EnableSQLServerNetworkProtocol('Np', True); // Named Pipes 
    finally 
     CoUninitialize; 
    end; 
except 
    on E:EOleException do 
     Writeln(Format('EOleException %s %x', [E.Message,E.ErrorCode])); 
    on E:Exception do 
     Writeln(E.Classname, ':', E.Message); 
end; 
Writeln('Press Enter to exit'); 
Readln; 
end.

注：此代码必须在安装SQL Server在同一台机器，如果你想要做这个任务远程您必须提供正确的执行，登录参数（用户，传递，服务器）到WMI连接。

要设置IP地址和端口，您可以使用ServerNetworkProtocolIPAddress和ServerNetworkProtocolProperty类。

来源

2014-01-29 06:39:12 RRUZ

^+ 1。 WMI能为我做啤酒吗？ :) – whosrdaddy

+1并被接受，即使我仍然直接使用注册表（WMI可以停止，注册表不能） –

以编程方式配置SQL Server TCP设置

回答

相关问题