批处理文件解析JSON

-2

这是我的JSON我只想在批处理文件中设置从“stable”对象到变量（不含引号）的版本“1.1.3”。我希望它是动态的，也许在未来作曲家将其改为“版本”：“1.1.3.6”或甚至“版本”：“1.1.3-beta2”，我想获得版本的任何价值。批处理文件解析JSON

谢谢。

myFile.json

{ 
    "stable": [{"path": "/download/1.1.3/composer.phar", "version": "1.1.3", "min-php": 50300}], 
    "preview": [{"path": "/download/1.1.3/composer.phar", "version": "1.1.3", "min-php": 50300}], 
    "snapshot": [{"path": "/composer.phar", "version": "334d0cce6b056e7555daf4c68c48cbe40ee4d51a", "min-php": 50300}] 
}

来源

2016-07-03 Amigo

假设字段的位置永远不会改变，这是一个非常简单的for/f循环。你试过什么了？ – SomethingDark

是的，但我从“http://getcomposer.org/versions”得到它我不知道他们是否改变立场，有一个解析器为CMD，但我不知道它是如何工作不幸的是，http： //stedolan.github.io/jq – Amigo

对于皮特的爱！使用JSON解析器。数据已经分层。将对象化并挖掘层次结构比标记它并计算行/词更为优雅。

@echo off & setlocal 

set "jsonfile=test.json" 

set "psCmd="add-type -As System.Web.Extensions;^ 
$JSON = new-object Web.Script.Serialization.JavaScriptSerializer;^ 
$JSON.DeserializeObject($input).stable.version"" 

for /f %%I in ('^<"%jsonfile%" powershell -noprofile %psCmd%') do set "version=%%I" 

echo Version: %version%

作为额外的奖励，如果你反正调用PowerShell的片断，你也可以使用Invoke-WebRequest从网络获取JSON。

@echo off & setlocal 

set "jsonURL=https://getcomposer.org/versions" 

set "psCmd="add-type -As System.Web.Extensions;^ 
$JSON = new-object Web.Script.Serialization.JavaScriptSerializer;^ 
$JSON.DeserializeObject((Invoke-WebRequest %jsonURL%).content).stable.version"" 

for /f %%I in ('powershell -noprofile %psCmd%') do set "version=%%I" 

echo Version: %version%

如果需要使用XP/Vista的兼容性，或者如果你只是想运行比PowerShell的帮助更快的脚本，你可以使用JScript中来达到同样的效果。

@if (@CodeSection == @Batch) @then 
@echo off & setlocal 

set "URL=https://getcomposer.org/versions" 

for /f "delims=" %%I in ('cscript /nologo /e:JScript "%~f0" "%URL%"') do set "ver=%%I" 

echo Version: %ver% 

goto :EOF 
@end // end Batch/begin JScript hybrid code 

var htmlfile = WSH.CreateObject('htmlfile'), 
    x = WSH.CreateObject("Microsoft.XMLHTTP"); 

x.open("GET",WSH.Arguments(0),true); 
x.setRequestHeader('User-Agent','XMLHTTP/1.0'); 
x.send(''); 
while (x.readyState != 4) WSH.Sleep(50); 

htmlfile.write('<meta http-equiv="x-ua-compatible" content="IE=9" />'); 
var obj = htmlfile.parentWindow.JSON.parse(x.responseText); 
htmlfile.close(); 

WSH.Echo(obj.stable[0].version);

来源

2016-07-03 23:02:53 rojo

谢谢[rojo]（http://stackoverflow.com/users/1683264/rojo）你真棒，惊人的答案！ – Amigo

顺便说一句，谁是皮特？ – Amigo

Pete和Repete正坐在栅栏上。皮特掉了下来。谁离开了？ – rojo

如果我们假设的位置永远不变的代码是：

@echo off 
setlocal enableDelayedExpansion 
FOR /f "skip=1 tokens=5 delims=:," %%I IN (vers.json) DO IF NOT DEFINED ver SET "ver=%%I" 
set ver=%ver:"=% 
set ver=%ver: =% 
echo !ver!

来源

2016-07-03 19:45:59 Amigo

批处理文件解析JSON

回答

相关问题