子范围声明的问题

Question

我试图做到这一点，所以一旦输入不同的文本形状将改变颜色，但它说（'A''Z'）是'期望'的问题，但收到一个字符串文字''一个'' '。我不知道如何解决它。任何帮助表示感谢，谢谢！

type 
    TCapitalLetter = ('A' .. 'Z'); //subrange of type char 
    TDigit = ('0' .. '9'); //subrage of type char 

Answer 1

你的定义是接近的，但它并不完全正确：

type 
    TCapitalLetter = 'A'..'Z'; 
    TDigit = '0'..9'; 

从您的其他问题，但是，我不认为这就是你真正需要做的。您正在寻找会员资格（某些字符包含在该类型中），在这种情况下，您需要使用集合来完成。这是一个控制台应用程序你可以编译和测试：

program Project1; 

{$APPTYPE CONSOLE} 

uses 
    SysUtils; 

type 
    TCapitalLetters = TSysCharSet; 
    TDigits = TSysCharSet; 

const 
    CapitalLetters: TCapitalLetters = ['A'..'Z']; 
    Digits: TDigits = ['0'..'9']; 

var 
    Temp, Output: string; 
    Ch: Char; 

begin 
    Output := ''; 
    Temp := 'Seems A Nice Test Answer'; 
    for Ch in Temp do 
    if CharInSet(Ch, CapitalLetters) then 
     Output := Output + Ch; 

    WriteLn(Output); 
    ReadLn; 
end. 

对于德尔福的早期（非Unicode）的版本，你需要使用set of Char代替TSysCharSet，并使用一个稍微不同的语法为集合成员：

program Project1; 

{$APPTYPE CONSOLE} 

uses 
    SysUtils; 

type 
    TCapitalLetters = set of Char; 
    TDigits = set of Char; 

const 
    CapitalLetters: TCapitalLetters = ['A'..'Z']; 
    Digits: TDigits = ['0'..'9']; 

var 
    Temp, Output: string; 
    Ch: Char; 

begin 
    Output := ''; 
    Temp := 'Seems A Nice Test Answer'; 
    for Ch in Temp do 
    if Ch in CapitalLetters then 
     Output := Output + Ch; 

    WriteLn(Output); 
    ReadLn; 
end. 

输出测试应用程式：