Erlang函数重载

Question

我刚开始摆弄Erlang。 我见过很多，其中模式匹配的函数声明中使用的例子，像这样：

factorCount (N) -> 
    Sqrt = math:sqrt (N), 
    ISqrt = trunc(Sqrt), 
    if ISqrt == Sqrt -> factorCount (N, ISqrt, 1, -1); 
     true   -> factorCount (N, ISqrt, 1, 0) 
    end. 

factorCount (_N, ISqrt, Candidate, Count) when Candidate > ISqrt -> Count; 
factorCount (N, ISqrt, Candidate, Count) -> 
    case N rem Candidate of 
     0 -> factorCount (N, ISqrt, Candidate + 1, Count + 2); 
     _ -> factorCount (N, ISqrt, Candidate + 1, Count) 
    end. 

为什么做这样？ 例如

factorCount (_N, ISqrt, Candidate, Count) when Candidate > ISqrt -> Count; 
factorCount (N, ISqrt, Candidate, Count) -> 

为什么这不仅仅是一个函数的内部条件呢？

Answer 1

一个原因是可读性和可维护性。函数内部的条件倾向于使代码由于额外的缩进而蠕变到正确的位置，并且与身体中的额外条件结合使得更长的函数更难以阅读，推理和维护。

另一个原因是，功能常有的先决条件，而后卫往往可以帮助表达这些先决条件更清楚不是嵌入在函数体中的代码。

还有一个原因是模式匹配的参数总是发生在函数被调用时，因为这基本上是函数参数如何获得它们的绑定，所以在警卫中使用这些绑定值是很自然的。卫兵是模式匹配的一种扩展，允许您检查模式匹配无法检查的事情。

Answer 2

此外Steve'sanswer，这将是比较明显的，如果我重写代码：

factorCount(_N, ISqrt, Candidate, Count) 
    when Candidate > ISqrt -> 
    Count; 
factorCount(N, ISqrt, Candidate, Count) 
    when N rem Candidate =:= 0 -> 
    factorCount(N, ISqrt, Candidate + 1, Count + 2); 
factorCount(N, ISqrt, Candidate, Count) -> 
    factorCount(N, ISqrt, Candidate + 1, Count). 

它成为代码更加明显，你结合的图案带着卫兵匹配：

merge([{K, V1} | T1], [{K, V2} | T2]) -> 
    [{K, [V1, V2]} | merge(T1, T2)]; 
merge([{K1, V1} | T1], [{K2, _} | _] = L2) 
    when K1 < K2 -> 
    [{K1, [V1]} | merge(T1, L2)]; 
merge(L1, [{K2, V2} | T2]) -> 
    [{K2, [V2]} | merge(L1, T2)]; 
merge(L1, []) -> 
    [{K, [V]} || {K, V} <- L1]. 

会如果我将第二个和第三个函数子句组合在一起，只是为了在函数子句中进行比较，没有多大意义。