在Stata中计算唯一值

Question

codebook是Stata中的一个伟大命令。它描述数据内容也只是标识唯一值

sysuse auto, clear 
codebook mpg, compact 

英里的唯一值数为21综观命令的帮助下，它似乎并不可能存储该值。我错了吗？

我知道有其他方法可以计算Stata中的number of unique values，但将此功能添加到codebook命令中会很方便。

Answer 1

您可以轻松地编写一个包装为使用尼克的distinct命令从SSC来存储你想要的标量（S）的信息codebook。

根据我的经验，这种包装方式已经被证明是远远超过要求在StataCorp漂亮的人对他们不参与互联网论坛上改变他们的命令更有效

下面是一个例子：

/* (1) You can stick this into a file called mycodebook.ado in /ado/personal (use adopath to see exact location) */ 
capture program drop mycodebook 
program mycodebook, rclass 
syntax [varlist] [if] [in][, *] 
codebook `varlist' `if' `in', `options' 
capture ssc install distinct 
foreach var of varlist `varlist' { 
    qui distinct `var' `if' `in' 
    return scalar nv_`var' = r(ndistinct) 
} 
end 

/* (2) example with mycodebook */ 
sysuse auto, clear 
mycodebook price mpg rep78 if foreign==0, compact 
return list 

最后这部分会给你：

. mycodebook price mpg rep78 if foreign==0, compact 

Variable Obs Unique  Mean Min Max Label 
------------------------------------------------------------------------------------------------- 
price  52  52 6072.423 3291 15906 Price 
mpg   52  17 19.82692 12  34 Mileage (mpg) 
rep78  48  5 3.020833  1  5 Repair Record 1978 
------------------------------------------------------------------------------------------------- 

. return list 

scalars: 
      r(nv_rep78) = 5 
      r(nv_mpg) = 17 
      r(nv_price) = 52 

然后，您可以做喜欢的东西（或者不管它是什么，你想这些做）：

gen x=r(nv_rep78) 

Answer 2

是的，你是错的

ssc install egenmore 
egen unique_values=nvals(mpg)