如何在Qt中实现搜索功能Quick folderListmodel ??

我想实现搜索功能，我的音乐播放器完全用Qml 写成。在我的情况下，我启动了一个qml Filedialog从文件系统获取文件夹，然后我使用folderListModel通过ListView列出它们。我想通过列表搜索任何线索我怎么能做到这一点？如何在Qt中实现搜索功能Quick folderListmodel ??

请不要建议使用C++。也不建议我在foldelistmodel中使用nameFilters :["*."]因为它不会工作它只根据文件扩展名而不是文件名进行过滤

来源

2015-04-16 bulldog68

实际上nameFilters确实允许按文件名进行过滤。使用一种破解，甚至可以使其不区分大小写。

这里是一个丑陋，但工作示例：

import QtQuick 2.3 
import QtQuick.Controls 1.2 
import Qt.labs.folderlistmodel 2.1 

Item { 
    width: 300 
    height: 300 

    FolderListModel 
    { 
     id: folderListModel 
    } 

    function updateFilter() 
    { 
     var text = filterField.text 
     var filter = "*" 
     for(var i = 0; i<text.length; i++) 
      if(!caseSensitiveCheckbox.checked) 
       filter+= "[%1%2]".arg(text[i].toUpperCase()).arg(text[i].toLowerCase()) 
      else 
       filter+= text[i] 
     filter+="*" 
     print(filter) 
     folderListModel.nameFilters = [filter] 
    } 

    Row 
    { 
     spacing: 5 
     Text {text:"Filter"} 
     TextField 
     { 
      id: filterField 
      onTextChanged: updateFilter() 
     } 

     Text {text:"Case Sensitive"} 
     CheckBox 
     { 
      id: caseSensitiveCheckbox 
      checked: false 
      onCheckedChanged:updateFilter() 
     } 
    } 

    ListView 
    { 
     anchors.fill: parent 
     anchors.topMargin: 30 
     model:folderListModel 
     delegate: Text{text: model.fileName} 
    } 

}

来源

2015-04-16 16:08:57 Yoann

感谢的人它就像魅力:)妳对我来说我已经从多个然后一个星期我都试过了挖这个生命的救星，你来了，如同神只有56行代码与一个工作示例感谢很多:) – bulldog68

使用DelegateModel：

与DelegateModelGroup进行排序和筛选委托项目。

假设你有一个函数使用文件名过滤文件，

function willBeShownOnView(filename){ /* ... */ }

你可以通过更多的角色（fileSize，fileIsDir，...）或过滤字符串由用户如果输入扩展这个功能你需要在这个函数中实现过滤逻辑。

接下来，创建一个DelegateModel与filterGroup：

DelegateModel { 
    id: delegateModel 
    model: FolderListModel{id: folderModel} 
    groups: [ 
     DelegateModelGroup { 
      name: "filterGroup"; includeByDefault: true 
     } 
    ] 
    filterOnGroup: "filterGroup" 
    delegate: MyFileDisplayComponent{/* ... */} 

    function applyFilter(){ /* see below */} 
}

正如includeByDefault: true，在folderModel的所有项目都包含在filterGroup。当我们applyFilter，一些项目应该从这个组中删除。例如，

function applyFilter(){ 
    var numberOfFiles = folderModel.count; 
    for (var i = 0; i < numberOfFiles; i++){ 
     var fileName = folderModel.get(i, "fileName"); 

     if (willBeShownOnView(fileName)){items.addGroups(i, 1, "filterGroup");} 
     else {items.removeGroups(i, 1, "filterGroup");} 
    } 
}

applyFilter后叫，只有通过willBeShownOnView添加到filterGroup文件。而财产filterOnGroup: "filterGroup"说代表模型只包含filterGroup内的项目。因此，我们可以用一个简单的ListView显示结果：

ListView { 
    model: delegateModel 
    //... 
}

来源

2015-04-19 02:24:50 mcchu

谢谢你:) – bulldog68

如何在Qt中实现搜索功能Quick folderListmodel ??

回答

相关问题