将数据从socket通信传递到用户界面

Question

在我当前的项目中，我发送和接收来自serversocket/clientsocket（TCP）的textmessages，就像聊天（我的项目是用VB.NET编写的）。只要我将发送的字节转换为字符串并将它们呈现在msgbox（）中，就可以工作。 此代码处理该部分：

Try 
    client = ar.AsyncState 
    client.EndReceive(ar) 
    client.BeginReceive(bytes2, 0, bytes2.Length, SocketFlags.None, New AsyncCallback(AddressOf OnRecieve), client) 
    Try 
     Dim message As String = System.Text.ASCIIEncoding.ASCII.GetString(bytes2) 
     MsgBox(message) 
     Array.Clear(bytes2, bytes2.GetLowerBound(0), bytes2.Length) 
    Catch ex As Exception 
     MsgBox("Error writing received message") 
    End Try 
Catch ex As Exception 
    MsgBox("Error receiving message from server") 
End Try 

到目前为止好。但是，当我尝试将“MsgBox（消息）”更改为label1.text =消息时，出现错误：“写入收到的消息时出错”。那么，我的问题就是为什么会发生这种情况，我可以采取什么措施来纠正它，以便我的套接字能够接收可添加到文本框和UI中其他内容的信息？

在此先感谢您的帮助，您可以提供

Answer 1

使用委托和的BeginInvoke（）正确元帅调用主UI线程：

Private Sub OnRecieve(ar As IAsyncResult) 
    Try 
     client = ar.AsyncState 
     client.EndReceive(ar) 

     Try 
      Dim message As String = System.Text.ASCIIEncoding.ASCII.GetString(bytes2) 
      NewMessage(message) 
     Catch ex As Exception 
      MsgBox("Error writing received message") 
     Finally 
      Array.Clear(bytes2, bytes2.GetLowerBound(0), bytes2.Length) 
     End Try 

     client.BeginReceive(bytes2, 0, bytes2.Length, SocketFlags.None, New AsyncCallback(AddressOf OnRecieve), client) 
    Catch ex As Exception 
     MsgBox("Error receiving message from server") 
    End Try 
End Sub 

Private Delegate Sub MessageDelegate(ByVal msg As String) 

Private Sub NewMessage(ByVal msg As String) 
    If Me.InvokeRequired Then 
     Me.BeginInvoke(New MessageDelegate(AddressOf NewMessage), New Object() {msg}) 
    Else 
     Label1.Text = msg 
    End If 
End Sub