Perl从调用模块导入变量

Question

我有一个Perl模块（Module.pm），用于初始化一些变量，其中一些我想将它导入（$ VAR2，$ VAR3）到其可能载入的其他子模块中执行。

我目前正在设立Module.pm的方法如下：

package Module::SubModule1; 

use warnings; 
use strict; 
use Carp; 

use vars qw(); 

sub new { 
    my ($package) = @_; 
    my $self = {}; 
    bless ($self, $package); 
    return $self; 
} 

我希望能够导入$ VAR2：

package Module; 

use warnings; 
use strict; 

use vars qw($SUBMODULES $VAR1 $VAR2 $VAR3); 

require Exporter; 
our @ISA = qw(Exporter); 
our @EXPORT = qw($VAR2 $VAR3); 

sub new { 
    my ($package) = @_; 
    my $self = {}; 
    bless ($self, $package); 
    return $self; 
} 

sub SubModules1 { 
    my $self = shift; 
    if($SUBMODULES->{'1'}) { return $SUBMODULES->{'1'}; } 

    # Load & cache submodule 
    require Module::SubModule1; 
    $SUBMODULES->{'1'} = Module::SubModule1->new(@_);  
    return $SUBMODULES->{'1'}; 
} 

sub SubModules2 { 
    my $self = shift; 
    if($SUBMODULES->{'2'}) { return $SUBMODULES->{'2'}; } 

    # Load & cache submodule 
    require Module::SubModule2; 
    $SUBMODULES->{'2'} = Module::SubModule2->new(@_);  
    return $SUBMODULES->{'2'}; 
} 

每个子模块的结构如下和$ VAR3变量导入每个子模块，而不必将它们作为$ Module :: VAR2和$ Module :: VAR3引用。我注意到调用脚本能够以所需的方式访问我在Module.pm中导出的两个变量，但是SubModule1.pm和SubModule2.pm仍需要将变量引用为Module.pm。

我试图更新每个子模块如下不幸的是没有工作，我希望：

package Module::SubModule1; 

use warnings; 
use strict; 
use Carp; 

use vars qw($VAR2 $VAR3); 

sub new { 
    my ($package) = @_; 
    my $self = {}; 
    bless ($self, $package); 
    $VAR2 = $Module::VAR2; 
    $VAR3 = $Module::VAR3; 
    return $self; 
} 

请让我知道我能成功地从Module.pm出口$ VAR2和$ VAR3到每个子模块。在此先感谢您的帮助！

Answer 1

在你的子模块，你忘了说

use Module; 

？从另一个包（称为Module::Submodule9）调用use Module将尝试运行Module::import方法。既然你没有这个方法，它会调用Exporter::import方法，那就是将Module的变量输出到Module::Submodule9命名空间的魔法会发生的地方。

---

在你的程序中只有一个Module命名空间，只有一个（全局）变量$Module::VAR2的实例。导出会在其他名称空间中为此变量创建别名，因此可以通过不同的方式访问相同的变量。在一个单独的脚本试试这个：

package Whatever; 
use Module; 
use strict; 
use vars qw($VAR2); 

$Module::VAR2 = 5; 
print $Whatever::VAR2; # should be 5. 
$VAR2 = 14;    # same as $Whatever::VAR2 = 14 
print $Module::VAR2;  # should be 14 

Answer 2

那么有简单的方法：

在M.pm：

package M; 

use strict; 
use warnings; 

#our is better than "use vars" for creating package variables 
#it creates an alias to $M::foo named $foo in the current lexical scope 
our $foo = 5; 

sub inM { print "$foo\n" } 

1; 

在M/S.pm

package M; 

#creates an alias to $M::foo that will last for the entire scope, 
#in this case the entire file 
our $foo; 

package M::S; 

use strict; 
use warnings; 

sub inMS { print "$foo\n" } 

1; 

在脚本中：

#!/usr/bin/perl 

use strict; 
use warnings; 

use M; 
use M::S; 

M::inM(); 
M::S::inMS(); 

但我会建议反对这一点。全局变量不是一种好的做法，模块之间共享全局变量更加糟糕。