Clojure宏：在宏内部执行代码

Question

我想创建一个宏，以便我可以在变量本身中添加变量名。我有这个Unit的记录。其name成员存储将创建的变量的名称。 即(def a-variable (->Unit 1 1 "a-varible")) 但我不想自己传递变量名称。

我认为宏可以派上用场。 :)

下面是代码：

(defrecord Unit 
    [value gradient name] 
    Object 
    (toString [_] 
    (str name " : "))) 


(defmacro create-unit1 [var-name & body] 
    `(def ~var-name ~(concat body (list (name var-name))))) 

(defmacro create-unit2 [var-name & body] 
    `(def ~var-name (concat ~@body (list (name '~var-name))))) 

但他们都不是给我写代码：

neurals.core> (macroexpand '(create-unit1 a (->Unit 1.0 0.0))) 
(def a ((->Unit 1.0 0.0) "a")) 

neurals.core> (macroexpand '(create-unit2 a (->Unit 1.0 0.0))) 
(def a (clojure.core/concat 
     (->Unit 1.0 0.0) (clojure.core/list 
          (clojure.core/name (quote a))))) 
neurals.core> 

我想：

(def a (->Unit 1.0 0.0 (clojure.core/name (quote a)))) 

什么是正确的方式在宏内执行concat？

Answer 1

您可以通过删除解决您的代码&在create-unit1：

(defmacro create-unit1 [var-name body] 
    `(def ~var-name ~(concat body (list (name var-name))))) 

(macroexpand `(create-unit1 a (->Unit 1.0 1.0))) 
;; => (def user/a (user/->Unit 1.0 1.0 "a")) 

您还可以添加的语法糖一点点：

(defmacro create-unit1 [var-name body] 
    `(def ~var-name (~@body ~(name var-name)))) 

或者，让这一切更地道：

(defmacro defunit [sym value gradient] 
    `(def ~sym (->Unit ~value ~gradient ~(name sym)))) 

(defunit a 1.0 1.0) 
;; => #user.Unit{:value 1.0, :gradient 1.0, :name "a"}