是否有可能使用frege与Play框架

Question

我正在寻找新项目的语言。这是基于Web的项目，我想采用REST架构。

我也想要一个函数编程语言。我可以选择Haskell（因为它很酷）和Scala（因为Play框架）。

经过很少的研究，找出它与语言之间的主要区别之后，我发现了Frege，一种运行在JVM上的类似Haskell的语言。

所以我的问题是，因为Frege运行在JVM上，所以可以在Frege中使用Play框架吗？

Answer 1

下面是一个简单的应用程序，演示如何使用Frege with Play。由于Play支持Java，所以使用Frege的Java API实际上非常简单，即使我们还没有对Frege的本地Play支持。该应用程序基本上是JSON-in和JSON-out。 Frege程序从JSON POST请求中读取参数，并以迎合用户的JSON响应作出响应。

播放conf/routes：

POST  /greet      helloplay.FregeApplication.greet() 

现在实际的“商业逻辑”弗雷格：

module helloplay.FregeApplication where 

import Data.JSON 
import helloplay.Play 

data GreetingRequest = GreetingRequest { name :: String } 

data GreetingResponse = GreetingResponse { message :: String } 

instance FromJSON GreetingRequest where 
    fromJSON (Struct fs) = do 
     name <- field "name" fs 
     pure $ GreetingRequest name 
    fromJSON invalid = fail ("Invalid JSON for Greeting Request: " ++ show invalid) 

instance ToJSON GreetingResponse where 
    toJSON (GreetingResponse message) = Struct [ assoc "message" message ] 

greet :: GreetingRequest -> GreetingResponse 
greet request = GreetingResponse $ "Hello, " ++ request.name 

webMain :: Request -> IO ResultStatus 
webMain request = do 
    let jsonRequest = parseJSON request.body.asJson.toString 
    return $ either badRequest (ok . show . toJSON . greet) jsonRequest 

{- 
- This makes the Frege module extend Play Controller class so that it can be configured to handle a route. 
-} 
native module type PlayController where { 
    public static play.mvc.Result greet() { 
     return frege.runtime.Delayed.forced(
      frege.prelude.PreludeBase.TST.performUnsafe(webMain(request())) 
     ); 
    } 
} 

这里我们定义了相应的请求和响应和JSON转换为那些FromJSON和2种类型ToJSON输入类实例。 webMain函数采用播放Request并从JSON请求中读取name，并返回包含在播放的Result.Status中的JSON响应。 webMain函数是为Play控制器提供实现的函数。播放控制器是扩展Play的play.mvc.Controller的类。通过在Frege源文件中声明native module，我们可以使Frege模块扩展Java类。 webMain函数也是一个IO操作，所以我们必须在某些时候评估某些事情的发生，这是底层Controller中的Java方法通过调用Frege的ST.performUnsafe然后强制从可能的thunk得到结果，否则应用程序会只是热身CPU :)

这里的类型，如Request，ResultStatus，PlayController和功能，如ok，badRequest都来自游戏的框架，所以我们必须添加本地绑定弗雷格提其纯度或可能的空值等，这是一件好事，因为弗雷格是一种纯粹的语言，并没有null的概念，我们必须明确提及可能的副作用或Maybe编译器的空值与Scala不同，您可以调用任何Java方法。

所效力的弗雷格本地绑定：

module helloplay.Play where 

data PlayController = native play.mvc.Controller 

data Result = pure native play.mvc.Result 

data ResultStatus = pure native play.mvc.Results.Status 

pure native badRequest play.mvc.Results.badRequest :: String -> ResultStatus 

data Request = pure native play.mvc.Http.Request where 
    pure native body :: Request -> RequestBody 

data RequestBody = pure native play.mvc.Http.RequestBody where 
    pure native asText :: RequestBody -> String 
    pure native asJson :: RequestBody -> JsonNode 

data JsonNode = pure native com.fasterxml.jackson.databind.JsonNode where 
    pure native asText :: JsonNode -> String 
    pure native toString :: JsonNode -> String 

pure native ok play.mvc.Results.ok :: String -> ResultStatus 

这就是它！我们可以运行它：

activator run

然后

$ curl --header "Content-type: application/json" --request POST --data '{"name": "PlayFrege"}' http://localhost:9000/greet 

{"message" : "Hello, PlayFrege"} 

弗雷格有一个SBT plugin，可以用来编译弗雷格源的播放项目。如果有人想尝试一下，我已经在Github推这个示例应用程序。