如何解析日期并在Perl中转换时区？

Question

我在Perl中使用了localtime函数来获取当前日期和时间，但需要解析现有日期。我有以下格式的GMT日期：“20090103 12:00”我想将它解析成我可以使用的日期对象，然后将GMT时间/日期转换为当前时区，即当前的东部标准时间。所以我想将“20090103 12:00”转换为“20090103 7:00”，关于如何做到这一点的任何信息将不胜感激。

Answer 1

因为内置在日期处理接口中的Perl有点笨拙，你最终会传递大约六个变量，所以更好的方法是使用DateTime或Time::Piece。 DateTime是全部歌曲，全部跳舞的Perl日期对象，并且您可能最终想要使用它，但Time :: Piece更简单且完全适合此任务，具有5.10版本的优势，并且该技术是两者基本相同。

下面是使用Time :: Piece和strptime的简单灵活的方法。

#!/usr/bin/perl 

use 5.10.0; 

use strict; 
use warnings; 

use Time::Piece; 

# Read the date from the command line. 
my $date = shift; 

# Parse the date using strptime(), which uses strftime() formats. 
my $time = Time::Piece->strptime($date, "%Y%m%d %H:%M"); 

# Here it is, parsed but still in GMT. 
say $time->datetime; 

# Create a localtime object for the same timestamp. 
$time = localtime($time->epoch); 

# And here it is localized. 
say $time->datetime; 

这就是对比的方式。

由于格式是固定的，正则表达式可以做得很好，但是如果格式发生变化，您必须调整正则表达式。

my($year, $mon, $day, $hour, $min) = 
    $date =~ /^(\d{4}) (\d{2}) (\d{2})\ (\d{2}):(\d{2})$/x; 

然后将其转换为Unix时代时间（自1月1秒钟，1970）

use Time::Local; 
# Note that all the internal Perl date handling functions take month 
# from 0 and the year starting at 1900. Blame C (or blame Larry for 
# parroting C). 
my $time = timegm(0, $min, $hour, $day, $mon - 1, $year - 1900); 

然后回本地时间。

(undef, $min, $hour, $day, $mon, $year) = localtime($time); 

my $local_date = sprintf "%d%02d%02d %02d:%02d\n", 
    $year + 1900, $mon + 1, $day, $hour, $min; 

Answer 2

任你选：

• DateTime :: *（或者，在datetime.perl.org）
• Date::Manip
• Date::Calc（2004年最后一次更新）

还有数不胜数的人，毫无疑问，但他们可能是最有力的竞争者。

Answer 3

下面是一个例子，使用DateTime及其strptime格式模块。

use DateTime; 
use DateTime::Format::Strptime; 

my $val = "20090103 12:00"; 

my $format = new DateTime::Format::Strptime(
       pattern => '%Y%m%d %H:%M', 
       time_zone => 'GMT', 
       ); 

my $date = $format->parse_datetime($val); 

print $date->strftime("%Y%m%d %H:%M %Z")."\n"; 

$date->set_time_zone("America/New_York"); # or "local" 

print $date->strftime("%Y%m%d %H:%M %Z")."\n"; 

$ perl dates.pl 
20090103 12:00 UTC 
20090103 07:00 EST 

---

如果你本来想本地时间分析，这里是你会怎么办呢:)

use DateTime; 

my @time = (localtime); 

my $date = DateTime->new(year => $time[5]+1900, month => $time[4]+1, 
       day => $time[3], hour => $time[2], minute => $time[1], 
       second => $time[0], time_zone => "America/New_York"); 

print $date->strftime("%F %r %Z")."\n"; 

$date->set_time_zone("Europe/Prague"); 

print $date->strftime("%F %r %Z")."\n"; 

Answer 4

这就是我想要做的......

#!/usr/bin/perl 
use Date::Parse; 
use POSIX; 

$orig = "20090103 12:00"; 

print strftime("%Y%m%d %R", localtime(str2time($orig, 'GMT'))); 

你也可以使用Time::ParseDate和parsedate()而不是Date::Parse和str2time()。请注意，事实上的标准atm。似乎是DateTime（但您可能不想使用OO语法来转换时间戳）。

Answer 5

use strict; 
use warnings; 
my ($sec,$min,$hour,$day,$month,$year)=localtime(); 
$year+=1900; 
$month+=1; 
$today_time = sprintf("%02d-%02d-%04d %02d:%02d:%02d",$day,$month,$year,$hour,$min,$sec); 
print $today_time;