VBA - MsgBox一个二维数组（矩阵）

Question

我想使用MsgBox可视化二维矩阵（数组），但我有的代码并没有给我正确的表示。

Sub test() 

Dim M(22, 7) As Double 
TwoD_Array_Matrix_In_MSGBOX (M) 

End Sub 
'_________________________________________________________________________ 

Public Function TwoD_Array_Matrix_In_MSGBOX(arr As Variant) 

h = UBound(arr, 1) 
w = UBound(arr, 2) 
'MsgBox ("h = " & CStr(h + 1) & vbCrLf & "w = " & CStr(w + 1)) ' to check if the width and hight of the Matrix are correct 
Dim msg As String 

For i = 0 To w 
    For ii = 0 To h 
     msg = msg & arr(ii, i) & vbTab 
    Next ii 
    msg = msg & vbCrLf 
Next i 

MsgBox msg 

End Function 

这是结果我得到：

Answer 1

你有w和h互换。

Dim msg As String 

For i = 0 To h 
    For ii = 0 To w 
     msg = msg & arr(i, ii) & vbTab 
    Next ii 
    msg = msg & vbCrLf 
Next i 

MsgBox msg 

Answer 2

这个完美的作品对我来说

Private Sub this() 
    Dim this(22, 7) As Integer 
    Dim msg$ 
    For i = LBound(this, 1) To UBound(this, 1) 
     For j = LBound(this, 2) To UBound(this, 2) 
      msg = msg & this(i, j) & vbTab 
     Next j 
    Next i 
    MsgBox msg 
End Sub 

Answer 3

这可能是更灵活地编写一个函数返回一个字符串，排序的2维连接，它允许你选择项目分隔符（默认为vbTab）和行分隔符（默认为vbCrLf）。

您可以MsgBox这个字符串 - 或者把它写入立即窗口 - 或（与选择作为分隔符的一个逗号） - 写入到一个CSV文件，等：

Function MatrixJoin(M As Variant, Optional delim1 As String = vbTab, Optional delim2 As String = vbCrLf) As String 
    Dim i As Long, j As Long 
    Dim row As Variant, rows As Variant 

    ReDim rows(LBound(M, 1) To UBound(M, 1)) 
    ReDim row(LBound(M, 2) To UBound(M, 2)) 

    For i = LBound(M, 1) To UBound(M, 1) 
     For j = LBound(M, 2) To UBound(M, 2) 
      row(j) = M(i, j) 
     Next j 
     rows(i) = Join(row, delim1) 
    Next i 
    MatrixJoin = Join(rows, delim2) 
End Function 

测试的条件：

Sub test() 
    Dim A As Variant 
    A = Range("A1:B3").Value 
    MsgBox MatrixJoin(A) 
    Debug.Print MatrixJoin(A, ",", ";") 
End Sub 

截图输出的：

---