如何获取另一个软件包所需的所有软件包的列表

Question

我的应用程序使用了运行时软件包，我想获取其中一个软件包所需的所有软件包的列表。

实施例：

PackA.bpl需要PackB.bpl和PackC.bpl。

如何在运行时从PackA.bpl获取所需的软件包？ （在这个例子中，它们是PackB.bpl和PackC.bpl）

Answer 1

您可以使用SysUtils的GetPackageInfo。 Here是一个使用它枚举包中编译的单元列表的示例（在您的情况下，在您的回调检查ntRequiresPackage而不是）。例如：

procedure GetRequiredPackageName(const Name: string; NameType: TNameType; Flags: Byte; Param: Pointer); 
var 
    Names: TStrings absolute Param; 
begin 
    case NameType of 
    ntRequiresPackage: 
     Names.Add(Name); 
    end; 
end; 

procedure GetRequiredPackageNames(Module: HMODULE; Names: TStrings); 
var 
    Flags: Integer; 
begin 
    Names.BeginUpdate; 
    try 
    GetPackageInfo(Module, Names, Flags, GetRequiredPackageName); 
    finally 
    Names.EndUpdate; 
    end; 
end; 

function ListRequiredPackages(HInstance: NativeInt; Data: Pointer): Boolean; 
var 
    Names: TStrings absolute Data; 
    I: Integer; 
begin 
    Result := True; 
    Names.Clear; 
    GetRequiredPackageNames(HInstance, Data); 
    Writeln(Format('%s requires: %d packages', [ExtractFileName(GetModuleName(HInstance)), Names.Count])); 
    if Names.Count > 0 then 
    for I := 0 to Names.Count - 1 do 
     Writeln(Names[I]); 
end; 

procedure Main; 
var 
    Names: TStringList; 
    I: Integer; 
begin 
    Names := TStringList.Create; 
    try 
    EnumModules(ListRequiredPackages, Names); 
    Readln; 
    finally 
    Names.Free; 
    end; 
end; 

为了得到一个包的名字的手柄，你可以使用GetModuleHandle：

ListRequiredPackages(GetModuleHandle('PackA.bpl'), Names);