在2个CGI脚本中登录和注销会话

Question

我需要在用户登录时存储登录会话，并在用户注销系统或会话超时时删除登录会话。我使用Perl编码。我知道我可以在Perl中使用CGI :: Session模块，但是如何确保会话是由1个CGI脚本创建的，并被另一个CGI脚本移除。然后，系统的所有其他页面都必须检查会话是否存在，然后才能显示其内容。

当前，我使用以下代码在用户成功登录时创建新会话。

my $session = CGI::Session->new(); 
my $CGISESSID = $session->id(); 

但是，如何在另一个cgi脚本中将用户从会话中注销？我怀疑我可以只使用以下内容，因为$ session没有在其他cgi脚本中定义

$session->delete(); 
$session->flush(); 

任何想法？

Answer 1

CGI ::默认情况下，会话独立于脚本。所以你应该能够做到这一点。

只要不忘记以某种方式将会话ID保留在客户端上。它可以用cookie来完成，例如参见会话header()。 ID和会话对象将自动检索（如果保存正确）。

见CGI::Session new()

如果调用时没有任何参数，$ DSN默认的驱动程序：文件;串行：默认; ID：MD5

和CGI::Session::Driver::file。

您可以将它们配置为使用您喜欢的商店和设置。

---

基本例如 CGI脚本使用会话：

#!/usr/bin/perl 
use strict; 
use warnings; 

use CGI; 
use CGI::Carp qw(fatalsToBrowser); # show errors in browser 
use CGI::Session; 


# new query object 
my $q = CGI->new(); 

# new session object, will get session ID from the query object 
# will restore any existing session with the session ID in the query object 
my $s = CGI::Session->new($q); 


# print the HTTP header and set the session ID cookie 
print $s->header(); 


# print some info 

print "<pre>\n"; 

print "Hello!\n\n"; 
printf "Your session ID is: %s\n", $s->id; 
printf "This sessin is: %s\n", $s->is_new ? 'NEW': 'old'; 
printf "Stored session 'test' value: '%s'\n", $q->escapeHTML($s->param('test')); 
printf "CGI Params: %s\n", join ', ', $q->param; 


# handle the form submit 

if(defined $q->param('save')){ 
    # save param value in the session 
    $s->param('test', $q->param('test')); 
    printf "Set session value: '%s'\n", $q->escapeHTML($s->param('test')); 
} 
elsif(defined $q->param('delete')){ 
    # delete session 
    $s->delete; 
    print "Session will be deleted.\n"; 
} 

print "\n</pre>\n"; 


# simple HTML form 

printf <<'_HTML_', $q->escapeHTML($s->param('test')); 
<hr/> 
<form> 
Session value "test": <input type="text" value="%s" name="test"/> 
<button type="submit" name="save">Save Value</button> 
<button type="submit" name="delete">Delete session</button> 
</form> 
_HTML_ 

# eof (linebreak needed after _HTML_)