如何用一个字符串中的新值替换旧值的列表

Question

有一个old_new值的映射，在字符串中用new_values替换这些old_value的惯用方法是什么？

my_map = %{"old_value1": "new_value1", "old_value2": "new_value2"} 
str = "some string .......old_value1 fafdsfd old_value2 faaaaaaa" 

由于药剂是不可变的，我不知道该怎么做。

Answer 1

（我假设你的地图有串钥匙，而不是原子）

如果你的罚款由一个运行的替代品之一，你可以简单地使用Enum.reduce与String.replace：

iex(1)> my_map = %{"old_value1" => "new_value1", "old_value2" => "new_value2"} 
%{"old_value1" => "new_value1", "old_value2" => "new_value2"} 
iex(2)> str = "some string .......old_value1 fafdsfd old_value2 faaaaaaa" 
"some string .......old_value1 fafdsfd old_value2 faaaaaaa" 
iex(3)> Enum.reduce(my_map, str, fn {old, new}, str -> String.replace(str, old, new) end) 
"some string .......new_value1 fafdsfd new_value2 faaaaaaa" 

但是，如果你想并行运行它们，为了性能或者正确性（如果地图上的任何键匹配任何其他值，以前的解决方案将给出不同的结果），我会使用类似:binary.compile_pattern,:binary.match和模式匹配：

defmodule Main do 
    def replace(string, map) do 
    replace(string, map, :binary.compile_pattern(Map.keys(map)), "") 
    end 

    defp replace(string, map, pattern, acc) do 
    case :binary.match(string, pattern) do 
     {start, length} -> 
     <<before::binary-size(start), match::binary-size(length), rest::binary>> = string 
     replacement = map[match] 
     replace(rest, map, pattern, acc <> before <> replacement) 
     :nomatch -> 
     acc <> string 
    end 
    end 
end 

my_map = %{"old_value1" => "new_value1", "old_value2" => "new_value2"} 
str = "some string .......old_value1 fafdsfd old_value2 faaaaaaa" 
IO.puts Main.replace(str, my_map) 

输出：

some string .......new_value1 fafdsfd new_value2 faaaaaaa