如何创建从MDB到SQL Server的链接表

Question

我有一个应用程序在通过无线网络访问MDB数据库时遇到问题。

快速解决方案是在所有将其所有表连接到SQL Server数据库的工作站上有一个本地MDB文件吗？

这是一种避免必须重新编写应用程序中的所有数据访问代码的方法吗？

Answer 1

是的，这样做会很好。我们有许多用这种方式连接的客户。
然而，这不是一件容易的事。不确定是否所有的努力都会为自己付出代价。
而且您还有一些新的维护和部署问题。

遵循的步骤是这样的：

1）迁移你的表到SQLServer的
2）创建ODBC数据源将被用于连接到后端数据库
3）连接您的表
4）重命名您的连接表以删除模式限定符（例如“dbo_”），以便您的链接表具有与以前相同的名称。

现在该是测试所有代码的时候了。
希望你不必重写任何东西。

真正的问题在于您需要创建与原始ODBC数据源相匹配的客户端PC。另外，如果您重新分配前端数据库，则可能需要重新连接来自客户端PC的所有表。 你需要调用这样的功能：

Public Function UpdateODBCTables() As Boolean 

    On Error GoTo Exit_On_Error 
    Dim dbs As DAO.Database 
    Dim tdf As DAO.TableDef 
    Dim sDSN As String 
    Dim sDB As String 
    Dim sComputer As String 
    Dim sDesc As String 
    Dim sApp As String 
    Dim strConnect As String 

    sDSN = "YOUR_DSN_NAME" 
    sDB = "YOUR_DATABASE_NAME" 
    sComputer = "YOUR_COMPUTER_NAME" 
    sApp = "YOUR_APP_NAME" 
    sDesc = "DESCRIPTION_OF_YOUR_APP" 

    strConnect = "ODBC;DSN=" & sDSN & ";" & _ 
       "DATABASE=" & sDB & ";" & _ 
       "WSID=" & sComputer & ";" & _ 
       "TrustedConnection=Yes;" & _ 
       "Description=" & sDesc & ";" & _ 
       "APP=" & sApp ";" 
    Set dbs = CurrentDb 
    ' Loop over tabledefs of ODBC type and reconnect 
    For Each tdf In dbs.TableDefs 
     If tdf.Connect <> "" And Left(tdf.Connect, 4) = "ODBC" And Left(tdf.Name, 1) <> "~" Then 
      tdf.Connect = strConnect 
      tdf.RefreshLink 
     End If 
    Next 
    dbs.TableDefs.Refresh 
    UpdateODBCTables = True 

Exit_On_Return: 
    Set dbs = Nothing 
    Exit Function 

Exit_On_Error: 
    MsgBox Err.Description, vbCritical, "YOUR_MESSAGE_TITLE" 
    Resume Exit_On_Return 
End Function