Groovy的：动态地将属性添加到从内部类方法Groovy类

Question

我有以下代码：

class MyClass { 
    def myMethod() { 
     variable = "I am a variable" 
    } 

    def propertyMissing(String name) { 
     println "Missing property $name" 
    } 
} 

MyClass myClass = new MyClass(); 
myClass.myProperty 
myClass.myMethod(); 

在myClass.myProperty，Missing property myProperty印出到控制台。

但随后myClass.myMethod()，常规并没有试图去propertyMissing而只是抛出一个

groovy.lang.MissingPropertyException: No such property: variable for class: MyClass 

一些网上搜索表明，这是因为myClass.myProperty调用一个getter方法，其重定向到propertyMissing。

我猜测，在类方法中，groovy不通过getter方法获取变量，这就是为什么propertyMissing没有被调用？

有没有办法通过使用动态propertyMissing或getProperty或类似的东西来实现我想要做的事情？

P.S.我不想在myMethod中执行def variable = ...或String variable = ...。我希望myMethod内的语法保持为variable = ...，但在该方法之外添加任何内容都是可以接受的。

Answer 1

你可以让你的类extend Expando（Expando is described here）

class MyClass extends Expando { 
    def myMethod() { 
     variable = "I am a variable" 
    } 

    def propertyMissing(String name) { 
     println "Missing property $name" 
    } 
} 

MyClass myClass = new MyClass() 
myClass.myProperty 
myClass.myMethod() 
println myClass.variable 

您可以手工卷创建变量自己的后盾地图，并写get/setProperty方法自己一个类似的功能，即：

class MyClass { 

    def myMethod() { 
     variable = "I am a variable" 
    } 

    def propertyMissing(String name) { 
     println "Missing property $name" 
    } 

    def backingMap = [:] 

    Object getProperty(String property) { 
     if(backingMap[ property ] == null) { 
     propertyMissing(property) 
     } 
     else { 
     backingMap[ property ] 
     } 
    } 

    void setProperty(String property, Object value) { 
     backingMap[ property ] = value 
    } 
} 

MyClass myClass = new MyClass() 
myClass.myProperty 
myClass.myMethod() 
println myClass.variable 

虽然从source code for Expando可以看出，这款手卷版本的检查工作量少得多，我相信它少了;-)