如何在扩展显示器中连续显示Windows窗体（即使主要被锁定）

在我们的项目中，我们要求在连接到CPU的扩展显示中显示仪表板（Windows窗体）。如何在扩展显示器中连续显示Windows窗体（即使主要被锁定）

目前我们能够在扩展显示器中显示仪表板，但是一旦系统（主）锁定后，扩展显示屏就不会显示任何内容。

我们不允许对工作站锁定进行任何更改。

即使主锁定，我们也必须在扩展显示屏上显示仪表板。一旦仪表板发送到扩展显示器，是否有任何要删除对主要的依赖关系？

我们使用VS2013和C＃。

感谢， Srikk

2014-10-16 jSrikk

“我们不允许对工作站锁定做任何更改。”很确定这是一个Windows的东西，没有办法“修改工作站锁定”。为了扩大这一点，当你锁定计算机时，Windows会锁定所有显示 - 原因很明显。锁定电脑并仍然显示桌面/文件是没有意义的。除非您实际上没有“锁定”计算机，否则辅助显示屏将被窗口锁定（假设您使用的是操作系统）。 – user1274820 2014-10-16 20:32:31

“我们不能做任何修改相对于工作站锁定。”

很确定这是一个窗口的东西，没有办法“修改工作站锁定”。为了扩大这一点，当你锁定计算机时，Windows会锁定所有显示 - 原因很明显。锁定电脑并仍然显示桌面/文件是没有意义的。除非您实际上没有“锁定”计算机，否则辅助显示屏将被窗口锁定（假设您使用的是操作系统）。

为了扩大这一点，有可能没有真正锁定计算机，而是创建一个全局按键/鼠标钩子（不要忘记，你也需要去额外的长度，以锁定CTRL + ALT + 删除如果你想这样做）忽略所有按键/鼠标移动。

我没有使用C＃编写的代码，但这里是我写的AutoIt代码，它锁定我的键盘和鼠标，并在我的屏幕上显示飞行的nyan猫。如果有人按下某个键，它会通过windows API锁定计算机（真正的方式）。

;/////////////////////////////// 
;// Lock Code Created by DT // 
;/////////////////////////////// 
#include <WinApi.au3> 
#include <GUIConstantsEx.au3> 
#include <WindowsConstants.au3> 

Sleep(5000); 

;/////////////////////////////////////////////////////////////// 
;// Hook User32.dll to block Mouse/Keyboard Input and Monitor // 
;/////////////////////////////////////////////////////////////// 
Global $stub_KeyProc = DllCallbackRegister("_KeyProc", "int", "int;ptr;ptr") 
Global $stub_MouseProc = DllCallBackRegister("_MouseProc", "int", "int;ptr;ptr") 
Global $keyboardHook = _WinAPI_SetWindowsHookEx($WH_KEYBOARD_LL, DllCallbackGetPtr($stub_KeyProc), _WinAPI_GetModuleHandle(0), 0) 
Global $mouseHook = _WinAPI_SetWindowsHookEx($WH_MOUSE_LL, DllCallbackGetPtr($stub_MouseProc), _WinAPI_GetModuleHandle(0), 0) 

;////////////////////// 
;// Global Variables // 
;////////////////////// 
Global $lock = False         ;If a key is pressed, set this to True and handle it in our while loop (gets messy otherwise) 
Global $desktopSize = WinGetPos("Program Manager")  ;Get the desktop size from Program Manager 
Global $maxX = $desktopSize[2]; - 600     ;Set a Max X Position by using the width of our image and width of desktop 
Global $maxY = $desktopSize[3]; - 255     ;Set a Max Y position by using the height of our image and the height of desktop 
Global $splashX = Int(Random(1, $maxX-1))    ;Display our splash randomly in the acceptable space 
Global $splashY = Int(Random(1, $maxY-1))    ;Display our splash randomly in the acceptable space 
Global $splashXVel = Int(Random(10,20))     ;Setup a random velocity for our image 
Global $splashYVel = 0;Int(Random(-5,5))    ;Setup a random velocity for our image (No need for Y Velocity anymore) 

;//////////////////////////// 
;// Create and Display GUI // 
;//////////////////////////// 
$Form1 = GuiCreate("Locked",400,280,$splashX, $splashY, $WS_POPUP, $WS_EX_LAYERED)    ;Create a GUI Window (Layered For Transparency) 
$gifTest = ObjCreate("Shell.Explorer.2")              ;Create a Shell.Explorer Object to display a GIF 
$gifTest_ctrol = GuiCtrlCreateObj($gifTest,-5,-5,410,290)          ;Push it slightly out of our GUI bounds to hide the border 
;                        ;Create a variable to hold some simple HTML code that displays a GIF 
$URL = "about:<html><body bgcolor='#dedede' scroll='no'><img src='C:\Users\DT\Pictures\nyan-cat.gif'></img></body></html>" 
$gifTest.Navigate($URL)                   ;Point our shell explorer to our HTML code 
_WinAPI_SetLayeredWindowAttributes($Form1, 0xdedede, 255)          ;Set our transparency color to our html background to make everything transparent 
GUISetState(@SW_SHOW)                   ;And finally, display our GUI 

;/////////////////////////////////////////////////////// 
;// Function that is called whenever a key is pressed // 
;/////////////////////////////////////////////////////// 
Func _KeyProc($nCode, $wParam, $lParam)               ;Grab parameters from our DLL Hook 
    If $nCode < 0 Then Return _WinAPI_CallNextHookEx($keyboardHook, $nCode, $wParam, $lParam) ;If it's not actually a key being pressed call the next hook 
    $lock = True                     ;Otherwise, it's time to lock the computer 
    Return 1                      ;Don't call the next hook (supress key press) 
EndFunc 

;/////////////////////////////////////////////////////// 
;// Function that is called whenever the mouse moves // 
;/////////////////////////////////////////////////////// 
Func _MouseProc($nCode, $wParam, $lParam)       ;Grab parameters from our DLL Hook 
    randomizeVelocity()            ;randomize our splash velocity 
    randomizePosition()            ;and randomize its position 
    Return 1               ;then supress the mouse movement 
EndFunc 

;/////////////////////////////////////////////////////////////////////// 
;// Simple randomize functions to reuse code and for ease of reading // 
;/////////////////////////////////////////////////////////////////////// 
Func randomizeVelocity() 
    $splashXVel = Int(Random(10,20)) 
    ;$splashYVel = Int(Random(-3,3)) 
EndFunc 
Func randomizePosition() 
    $splashX = Int(Random(1, $maxX-1)) 
    $splashY = Int(Random(1, $maxY-1)) 
EndFunc 

;///////////////////////////////////////////////// 
;// Our program loop (main function basically) // 
;///////////////////////////////////////////////// 
hideTaskbar(); 
While 1                ;loop indefinitely (until we exit :)) 
    $splashX = $splashX + $splashXVel        ;Modify splash x position by velocity 
    $splashY = $splashY + $splashYVel        ;Modify splash y position by velocity 
    WinMove($Form1,"" , $splashX, $splashY)       ;and move the window 

    ;If $splashX >= $maxX Or $splashX <= 0 Then $splashXVel *= -1  ;if our splash image hits an edge 
    ;If $splashY >= $maxY Or $splashY <= 0 Then $splashYVel *= -1  ;reverse its velocity (can be buggy! ;)) 
    If $splashX >= $maxX Then 
     $splashY = Int(Random(1,$maxY-400)) 
     $splashX = -400; 
    EndIf  

    If $lock Then             ;If we have a message to lock the computer 
     DllCallbackFree($stub_KeyProc)        ;release our hooks 
     DllCallbackFree($stub_MouseProc) 
     _WinAPI_UnhookWindowsHookEx($keyboardHook) 
     _WinAPI_UnhookWindowsHookEx($mouseHook) 
     showTaskbar(); 
     Run("rundll32.exe user32.dll,LockWorkStation")    ;and lock the computer 
     Exit               ;then exit the program :) 
    EndIf 
    Sleep(40) 
WEnd 
;///////////////////////////////////////////////// 

Func hideTaskbar() 
    WinSetTrans("[Class:Shell_TrayWnd]", "", 0) 
    ControlHide('','', WinGetHandle("[CLASS:Button]")) 
EndFunc 
Func showTaskbar() 
    WinSetTrans("[Class:Shell_TrayWnd]", "", 255) 
    ControlShow('','', WinGetHandle("[CLASS:Button]")) 
EndFunc

enter image description here

编辑：

在问候的CTRL + ALT + DEL组合键（或其他Windows组合键），结账此链接信息关于如何禁用那些：

http://tamas.io/c-disable-ctrl-alt-del-alt-tab-alt-f4-start-menu-and-so-on/

来源

2014-10-16 20:41:08 user1274820

非常好的答案 – alykins 2014-10-16 20:50:45

我没有AutoIT来测试，但如果这是在运行并且用户按下Alt + F4（默认关闭前台应用程序），会发生什么？机器是否仍然锁定？如果没有，这不是一个解决方案，因为锁定工作站的目的是为了防止这是一个安全问题。 – 2014-10-16 20:52:17

AutoIt程序在后台运行，所以它不是可以用Alt + F4关闭的前台应用程序。在答案中我也说过：不要忘记，如果你想做正确的话，你还需要额外的长度来锁定CTRL + ALT + DELETE，因为这是真正的问题。如果你有专家的时间安排，可以按CTRL + ALT + DELETE，也许某种程度上通过盲运或某种方式关闭了程序 - 这就是我提到它的原因。 – user1274820 2014-10-16 20:57:05

如何在扩展显示器中连续显示Windows窗体（即使主要被锁定）

回答

相关问题