如何获取当前运行在vb6中的进程的文件名

Question

有没有办法从Excel或Word进程中查找当前打开的文件等？我想获得Windows中所有正在运行的进程以及它们当前打开的文件的列表。

Answer 1

是否有原因，你为什么使用vb6？

编辑： 我不知道，如果这会帮助你，但这里是一个链接，用一些例子来说明如何获得VB6进程列表：http://wiki.robotz.com/index.php/Process_List_and_Locate_VB6

Answer 2

如何使用正在运行的进程的列表VBA

Function getProcessInfo() 
''On Error Resume Next 
Dim objProcess, process, strNameOfUser 
ComputerName = "." 
Set objProcess = GetObject("winmgmts:{impersonationLevel=impersonate}\\" _ 
     & ComputerName & "\root\cimv2").ExecQuery("Select * From Win32_Process") 
For Each process In objProcess 
    If process.Name <> "System Idle Process" And process.Name <> "System" Then 
     ''Debug.Print process.Name 
     Debug.Print process.Name & "," & process.executablepath _ 
      & "," & process.Priority & "," & process.sessionid _ 
      & "," & strNameOfUser & "," & process.handlecount _ 
      & "," & process.ThreadCount 
    End If 
Next 

Set objProcess = Nothing 
End Function 

改自：http://www.windowsadminscripts.com/coding/networking/processes/

也许打开的窗口的列表可能更为有用：

Private Const GW_HWNDNEXT = 2 
Private Declare Function GetWindow Lib "user32" (ByVal hWnd As Long, ByVal wCmd As Long) As Long 
Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long 
Private Declare Function GetClassName Lib "user32" Alias "GetClassNameA" (ByVal hWnd As Long, ByVal lpClassName As String, ByVal nMaxCount As Long) As Long 
Private Declare Function GetWindowText Lib "user32" Alias "GetWindowTextA" (ByVal hWnd As Long, ByVal lpString As String, ByVal cch As Long) As Long 

Sub ListWins(Optional Title = "*", Optional Class = "*") 
    Dim hWndThis As Long 
    hWndThis = FindWindow(vbNullString, vbNullString) 
    While hWndThis 
     Dim sTitle As String, sClass As String 
     sTitle = Space$(255) 
     sTitle = Left$(sTitle, GetWindowText(hWndThis, sTitle, Len(sTitle))) 
     sClass = Space$(255) 
     sClass = Left$(sClass, GetClassName(hWndThis, sClass, Len(sClass))) 
     If sTitle Like Title And sClass Like Class Then 
      Debug.Print sTitle, sClass 
     End If 
     hWndThis = GetWindow(hWndThis, GW_HWNDNEXT) 
    Wend 
End Sub 

使用它，像这样：

ListWins "*.doc*" 

这将列出所有Word窗口包含标题.DOC