带键的XSL动态表列数据

我已经开始使用XSL并且遇到了唯一的动态列数据问题。我已阅读过类似的问题，但这种情况似乎有所不同，所以我没有看到这些解决方案在这个问题上的应用。带键的XSL动态表列数据

我有以下的样本数据集可以增长或与大量的<ID>和<Date>值缩水：

<Report> 
    <DataSets> 
    <Data> 
     <ID>1</ID> 
     <Date>201211</Date> 
    </Data> 
    <Data> 
     <ID>1</ID> 
     <Date>201211</Date> 
    </Data> 
    <Data> 
     <ID>1</ID> 
     <Date>201210</Date> 
    </Data> 
    <Data> 
     <ID>2</ID> 
     <Date>201209</Date> 
    </Data> 
    <Data> 
     <ID>1</ID> 
     <Date>201208</Date> 
    </Data> 
    <Data> 
     <ID>2</ID> 
     <Date>201208</Date> 
    </Data> 
    <Data> 
     <ID>3</ID> 
     <Date>201208</Date> 
    </Data> 
    <Data> 
     <ID>3</ID> 
     <Date>201208</Date> 
    </Data> 
    </DataSets> 
</Report>

我试图获得XSL代码来生成如下表：

ID 201208 201209 201210 201211 
1  1  0  1  2 
2  1  1  0  0 
3  2  0  0  0

这些列是动态的，列标题是<Date>元素的唯一值。这些行是唯一ID的集合，数据是每个<Date>的所述<ID>的计数。我正在努力的是为每个<Date>动态创建<ID>的计数。

到目前为止，我有以下XSL文件使用生成表的键，但正如您可以看到日期是硬编码atm。

<?xml version="1.0" encoding="UTF-8"?> 
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
       version="1.0" > 

<xsl:template match ="/" > 
<html> 
    <body> 
    <xsl:apply-templates select="Report/DataSets"/> 
    </body> 
</html> 
</xsl:template> 

<xsl:key name="Data_ID" match="Data" use="ID" /> 
<xsl:key name="Data_D" match="Data" use="Date"/> 
<xsl:template match="Report/DataSets" > 
<table> 
    <tr> 
    <th>ID</th> 
    <xsl:for-each select="Data[generate-id(.) = generate-id(key('Data_D', Date)[1])]"> 
     <xsl:sort select="Date"/> 
     <!-- Dynamically add headers for each Date Column --> 
     <th><xsl:value-of select="Date"/></th> 
    </xsl:for-each> 
    </tr> 
    <xsl:for-each select="Data[generate-id(.) = generate-id(key('Data_ID', ID)[1])]"> 
    <xsl:sort select="ID"/> 
    <tr> 
    <td><xsl:value-of select="ID"/></td> 
    <!-- Dynamically count IDs for each Date Column --> 
    <!-- How to do this step? --> 
    <td><xsl:value-of select="count(key('Data_ID', ID)[Date='201208'])"/></td> 
    <td><xsl:value-of select="count(key('Data_ID', ID)[Date='201209'])"/></td> 
    <td><xsl:value-of select="count(key('Data_ID', ID)[Date='201210'])"/></td> 
    <td><xsl:value-of select="count(key('Data_ID', ID)[Date='201211'])"/></td> 
    </tr> 
    </xsl:for-each> 
</table> 
</xsl:template> 
</xsl:stylesheet>

现在需要更换这些硬编码的条目

<td><xsl:value-of select="count(key('Data_ID', ID)[Date='201208'])"/></td> 
<td><xsl:value-of select="count(key('Data_ID', ID)[Date='201209'])"/></td> 
<td><xsl:value-of select="count(key('Data_ID', ID)[Date='201210'])"/></td> 
<td><xsl:value-of select="count(key('Data_ID', ID)[Date='201211'])"/></td>

动态代码？

来源

2013-07-30 JMO

您可以使用同一种for-each您所使用的标题

<!-- store the full set of Data in a variable - we will need it inside the for-eaches --> 
    <xsl:variable name="allData" select="Data"/> 
    <xsl:for-each select="$allData[generate-id(.) = generate-id(key('Data_ID', ID)[1])]"> 
    <xsl:sort select="ID"/> 
    <xsl:variable name="currentId" select="ID" /> 
    <tr> 
    <td><xsl:value-of select="$currentId"/></td> 
    <!-- Dynamically count IDs for each Date Column --> 
    <xsl:for-each select="$allData[generate-id(.) = generate-id(key('Data_D', Date)[1])]"> 
     <xsl:sort select="Date"/> 
     <td> 
     <xsl:value-of select="count(key('Data_ID', $currentId)[Date=current()/Date])"/> 
     </td> 
    </xsl:for-each> 
    </tr> 
    </xsl:for-each>

这里的窍门是从外for-each的ID保存在一个变量，所以你可以访问它，而你在里面内部for-each。

甲可能更有效的替代方案将是，以限定在两个ID和日期第三密钥

<xsl:key name="Data_ID_D" match="Data" use="concat(ID, '|', Date)" />

这将简化count表达

<xsl:for-each select="$allData[generate-id(.) = generate-id(key('Data_D', Date)[1])]"> 
    <xsl:sort select="Date"/> 
    <td> 
    <xsl:value-of select="count(key('Data_ID_D', concat($currentId, '|', Date)))"/> 
    </td> 
</xsl:for-each>

来源

2013-07-30 17:48:18

这种方法似乎不工作，我得到一张空桌子。额外的'for-each'的问题是上下文已经设置好了，并且你没有看到你可以移回路径来为日期创建一个新的集合。另外，尝试组合这两个键似乎并不奏效，因为这些键需要独立存在，并将结果合并到非唯一的行条目中。 – JMO

@JMO好点。您需要将外部上下文保存在另一个变量中，以便您可以在两个for-each选项上执行Muenchian技巧（请参阅编辑）。 –

啊，是的，它做到了。完美的作品，谢谢。 – JMO

带键的XSL动态表列数据

回答

相关问题