参考参数

Question

假设我们有一个子程序返回参考

sub aspirin { 
    my @items = qw(some items in here); 
    return \@items; 
} 

而另一子程序取一个数组引用

sub beetroot (\@) { 
    my $lst = shift; 
    print "$_\n" for @$lst; 
} 

我想从aspirin获取数组和饲料beetroot与它。我想这样做（的做法一个）

my $L = aspirin; 
beetroot $L; 

但解释抱怨，我需要做以下代替（方法乙）：

my $L = aspirin; 
beetroot @$L; 

所以我的问题是：

• 为什么不是方法A能正常工作？该参数实际上是一个Array引用，这是我们想要的;
• 是否需要复制整个列表内容而不进行赋值的解引用（如方法B中的那个）？ （我猜不是，因为没有明确的副本）。

谢谢您的回答

Answer 1

存在Perl原型来修改解析器的行为，这很少需要。这也不例外。

如果“beetroot”没有任何其他参数，那么您应该使用@_而不是数组引用。

sub aspirin { 
    my @items = qw'some items in here'; 
    return @items if wantarray; # return a list in list context 
    return \@items; 
} 

sub beetroot { 
    print "$_\n" for @_; 
} 

my $L = aspirin; 
beetroot @$L; 

# the follow examples require the version of aspirin from this answer 

my @L = aspirin; 
beetroot @L; 

beetroot aspirin; # aspirin called in list context 

这将带来额外的好处，即如果您只想输入元素列表，则无需解析解析器。

这适用于新版本，但不适用于问题中的版本。

beetroot qw'some items in here'; 
beetroot aspirin; # aspirin called in list context 

为了使它与问题中的问题一起工作，您必须创建一个匿名数组。有趣的是，这也适用于这个答案中的版本。

beetroot @{ [qw'some items in here'] }; 
# the follow examples use the version of aspirin from this answer 
beetroot @{ [aspirin] }; 
beetroot @{ scalar aspirin }; 
beetroot @{ aspirin }; 

---

如果你真的想 “beetroot” 与数组引用工作。 我会这样写。

sub beetroot{ 
    my($lst) = @_; # similar to my $lst = shift 
    print "$_\n" for @$lst; 
} 

my $L = aspirin; 
beetroot $L; 

my @L = aspirin; # using the aspirin from this answer 
beetroot \@L; 

beetroot [qw'some items in here']; 
# the follow examples use the version of aspirin from this answer 
beetroot scalar aspirin; # force aspirin to return an array reference 
beetroot [ aspirin ]; # copy the array 

这样，如果你想使用引用减少的Perl的内存占用，或者你有其他投入“beetroot”我只会写。

Answer 2

原型\@并不意味着数组引用。这意味着给我一个数组，但我会得到它的一个引用作为参数（见perldoc perlsub

报价：

任何反斜杠的原型人物代表实际的论点，即 绝对必须以该字符开始如部分的@_ 将是在 子程序调用中给出的实际参数的引用传递的值，通过施加到"\"该参数获得。

或换句话说，不要使用原型，除非你真的知道他们在做什么。