在运行时为复选框创建事件Excel VBA

Question

我正在修改此线程中的答案，使其适用于我的代码，但它不适用于我。

How to assign an event to multiple objects with excel vba?

一对夫妇的差别，我使用的是复选框，而不是一个组合框，但更重要的是，我创造我在运行时复选框。

这里是我的类：

Public WithEvents checkBox1 As MSForms.checkBox 


Private Sub checkBox1_Click() 
MsgBox "click" 
End Sub' 

模块代码：

Dim tbCollection As New Collection 

Sub macro1() 

Dim cbox As OLEObject 
Dim myCheckBox As New JohnClass 

Set cbox = ActiveSheet.OLEObjects.Add("Forms.CheckBox.1", Left:=Range("A1")) 
Set myCheckBox.checkBox1 = cbox.Object 
tbCollection.Add cbox 
end sub 

我可以看到我有新创建的复选框的参考，因为我可以更改标题，但是当我点击在它上面，没有任何反应。

Answer 1

您需要将自定义类的实例添加到集合中。更改

tbCollection.Add cbox 

到

tbCollection.Add myCheckBox 

更新：

似乎有一些问题，在运行时添加OLEObjects和运行任何其他代码。我不知道问题是什么，但这似乎起作用。

Public tbCollection As Collection 

Sub macro1() 

    ActiveSheet.OLEObjects.Add ClassType:="Forms.CheckBox.1", Left:=1, Top:=1 

    Application.OnTime Now, "AddToClass" 

End Sub 

Sub AddToClass() 

    Dim myCheckBox As JohnClass 

    Set tbCollection = New Collection 
    Set myCheckBox = New JohnClass 

    Set myCheckBox.CheckBox1 = ActiveSheet.OLEObjects(ActiveSheet.OLEObjects.Count).Object 
    tbCollection.Add myCheckBox 

End Sub