Excel Noob将Excel单元格复制到HTML文本框

Question

我必须每周将500-600单元格复制到文本框中所覆盖的网站中。我知道如何编写代码，所以我知道如何阅读源代码，但Excel现在不在我身边。我如何复制一个Excel单元格放置在某个文本字段中（我已经在下面分解了它）。现在我需要帮助重复它，直到它遇到一个空白单元格。

A1 = id='firstname0' 
A2 = id='middleinitial0' 
A3 = id='lastname0' 
A6 = id='ntlogin0' 

B1 = id='firstname1' 
B2 = id='middleinitial1' 
B3 = id='lastname1' 
B6 = id='ntlogin1' 

C1 = id='firstname2' 
C2 = id='middleinitial2' 
C3 = id='lastname2' 
C6 = id='ntlogin2' 

下面是一些网站的来源：

<td> 
    <input type='text' name='ntlogin[]' id='ntlogin0' /> 
</td> 

<td> 
    <input type='text' name='firstname[]' id='firstname0' /> 
</td> 

<td class='center'> 
    <input type='text' name='middleinitial[]' id='middleinitial0' size='1' /> 
</td> 

<td> 
    <input type='text' name='lastname[]' id='lastname0' /> 
</td> 

<td> 
    <input type='text' name='hiredate[]' id='hiredate0' /> 
</td> 

该网站问我有多少行创建。我可以用1个按钮来控制聘用日期部分。我无法控制网站，因此我无法对其进行任何更改。

Answer 1

您可以使用VBA库“Microsoft Internet控制”和“Microsoft HTML对象库”和完全自动化网页交互...

下面是一个宏做...若要进入宏代码，您可以使用Alt + F11进入Microsoft Visual Basic for Applications环境。
- 添加库引用（下Tools>References菜单）
- 添加代码模块
（Insert>Module下） - 下面的代码粘贴...修改他们的网址

代码将打开IE然后进入网页并等待你点击确定（完成任何你需要的操作后......也许登录，在某处导航，输入行数......）。然后，它将遍历您在电子表格中使用的所有列（使用Find填充numCols），并将单元格值放入具有相关ID的HTML元素中。它不会打到为你增加员工，以防万一出错，但图书馆确实给你的东西.Click()的能力。

我已经使用了这个几个自动化黑客，它似乎很可靠......困难的部分可以等待页面加载/更新 - 但你不应该有这个问题。

'References needed: "Microsoft Internet Controls" and "Microsoft HTML Object Library" 
' (add under menu Tools > References) 

Sub populate() 

    Dim ws As Worksheet 
    Set ws = Application.ActiveSheet 

    Dim appIE As InternetExplorer 
    Set appIE = New InternetExplorer 
    appIE.Visible = True 

    appIE.Navigate "http://localhost:8080/your_form" 

    If vbCancel = MsgBox("Make sure the page has loaded, enter the number of ids etc. etc. Then click OK", vbOKCancel) Then 
    Set appIE = Nothing 
    Exit Sub 
    End If 

    Dim counter As Integer, index As Integer, numCols As Integer 
    numCols = ws.Cells.Find(What:="*", After:=[A1], LookIn:=xlValues, SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Column 
    For counter = 1 To numCols 
    'A1 = id='firstname0' 
    'A2 = id='middleinitial0' 
    'A3 = id='lastname0' 
    'A6 = id='ntlogin0' 
    index = counter - 1 
    appIE.document.getElementById("firstname" & index).Value = ws.Cells(1, counter) 
    appIE.document.getElementById("middleinitial" & index).Value = ws.Cells(2, counter) 
    appIE.document.getElementById("lastname" & index).Value = ws.Cells(3, counter) 
    appIE.document.getElementById("ntlogin" & index).Value = ws.Cells(6, counter) 
    Next counter 

    Set appIE = Nothing 
    Set ws = Nothing 

    MsgBox "All done - hit Submit if all OK!" 

End Sub 

版本VALUES行

'References needed: "Microsoft Internet Controls" and "Microsoft HTML Object Library" 
' (add under menu Tools > References) 

Sub populate() 

    Dim ws As Worksheet 
    Set ws = Application.ActiveSheet 

    Dim appIE As InternetExplorer 
    Set appIE = New InternetExplorer 
    appIE.Visible = True 

    appIE.Navigate "http://localhost:8080/your_form" 

    If vbCancel = MsgBox("Make sure the page has loaded, enter the number of ids etc. etc. Then click OK", vbOKCancel) Then 
    Set appIE = Nothing 
    Exit Sub 
    End If 

    Dim counter As Integer, index As Integer, numRows As Integer 
    numRows = ws.Cells.Find(What:="*", After:=[A1], LookIn:=xlValues, SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row 
    For counter = 1 To numRows 
    'A1 = id='firstname0' 
    'B1 = id='middleinitial0' 
    'C1 = id='lastname0' 
    'D1 = id='ntlogin0' 
    index = counter - 1 
    appIE.document.getElementById("firstname" & index).Value = ws.Cells(counter,1) 
    appIE.document.getElementById("middleinitial" & index).Value = ws.Cells(counter,2) 
    appIE.document.getElementById("lastname" & index).Value = ws.Cells(counter,3) 
    appIE.document.getElementById("ntlogin" & index).Value = ws.Cells(counter,4) 
    Next counter 

    Set appIE = Nothing 
    Set ws = Nothing 

    MsgBox "All done - hit Submit if all OK!" 

End Sub