XSLT转换XML到XHTML

text 24 text 12 text times 12

你可以做这样的事情：

XML输入（修改为良好形成）

<doc> 
    <par font="Arial" size="24">text 24</par> 
    <par font="Arial" size="12">text 12</par> 
    <par font="Times New Roman" size="12">text times 12</par> 
</doc>

XSLT 1.0

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="xml" indent="yes"/> 
    <xsl:strip-space elements="*"/> 

    <xsl:template match="@*|node()"> 
     <xsl:copy> 
      <xsl:apply-templates select="@*|node()"/> 
     </xsl:copy> 
    </xsl:template> 

    <xsl:template match="doc"> 
     <html> 
      <xsl:apply-templates/> 
     </html> 
    </xsl:template> 

    <xsl:template match="par"> 
     <font> 
      <xsl:attribute name="style"> 
       <xsl:apply-templates select="@*"/> 
      </xsl:attribute> 
      <xsl:apply-templates select="node()"/> 
     </font> 
    </xsl:template> 

    <xsl:template match="par/@size"> 
     <xsl:value-of select="concat('font-size: ',.,';')"/> 
    </xsl:template> 
    <xsl:template match="par/@font"> 
     <xsl:value-of select="concat('font-family: ',.,';')"/> 
    </xsl:template> 

</xsl:stylesheet>

输出

<html> 
    <font style="font-family: Arial;font-size: 24;">text 24</font> 
    <font style="font-family: Arial;font-size: 12;">text 12</font> 
    <font style="font-family: Times New Roman;font-size: 12;">text times 12</font> 
</html>

此外，您还可以将match="par"更改为match="par[@font or @size]"，如果你只想输出如果它有一个font或size属性。

来源

2012-07-25 15:22:02

完美的作品！ – Sebange 2012-07-25 15:35:00

@DevNull这是一个很好的答案，但它并不完美。您的样式属性值中包含多余的分号。 – 2012-07-25 15:55:06

@ SeanB.Durkin - 尾随分号不是必需的，但它也不会伤害任何东西。 – 2012-07-25 17:25:00

对DevNull的调整。他是第一个正确答案。詹姆斯的答案是错的。

我只是是非常迂腐这里，但实际最简单的解决方案严密....是<击鼓声/> ....

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output method="xml" indent="yes" omit-xml-declaration="yes"/> 

<xsl:template match="/"> 
<xsl:for-each select="*/par"> 
    <font style="{ string-join(
    for $a in (@size|@font) return 
    concat('font-', if ($a except @font) then 'size' else 'family', ':', $a), 
    ';')}"> 
    <xsl:copy-of select="node()"/> 
    </font> 
</xsl:for-each> 
</xsl:template> 

</xsl:stylesheet>

上述XSLT 2.0样式表将改变此输入。 ..

<doc> 
    <par font="Arial" size="24">text 24</par> 
    <par font="Arial" size="12">text 12</par> 
    <par font="Times New Roman" size="12">text times 12</par> 
    <par font="Courier">No size specified!</par> 
    <par size="16">No font specified!</par> 
</doc>

...这个...输出

<font style="font-family:Arial;font-size:24">text 24</font> 
<font style="font-family:Arial;font-size:12">text 12</font> 
<font style="font-family:Times New Roman;font-size:12">text times 12</font> 
<font style="font-family:Courier">No size specified!</font> 
<font style="font-size:16">No font specified!</font>

一个小模板，style属性值中没有多余的分号！

没有提及需要什么XSLT版本。所以如果OP在XSLT 1.0上，那么这个解决方案可能对OP没有用。

来源

2012-07-25 16:34:54

B转换是由IE完成的我只是做了一些搜索，它似乎只接受XSLT-1.0。我添加标签。 – Sebange 2012-07-27 08:55:47

XSLT转换XML到XHTML

回答

相关问题