如何在F中模拟鼠标点击和按键＃

Question

我正在做一个应该移动鼠标并在代码中指定位置自动按下的程序。现在我已经设法移动光标使用这一行： Cursor.Position < - System.Drawing.Point（x，y）

我还没有发现的是如何模拟鼠标点击或按键。我唯一发现的就是MSDN的SendKeys Class（http://msdn.microsoft.com/en-us/library/system.windows.forms.sendkeys.aspx）。我试图模拟这个类的按键，但我得到一个运行时错误消息。

我使用的路线是： SendKeys.Send（“{ENTER}”）

错误消息我得到： “的SendKeys不能在此应用程序内运行，因为该应用程序不处理Windows消息要么改变处理消息的应用程序或使用SendKeys.SendWait方法。“

所以我用SendWait方法替换了它，但它似乎仍然没有发送按键。我该怎么做呢？我真正想要完成的程序能够做到的是将键和鼠标点击发送到已经在后台打开的另一个程序。例如，自动在Paint中绘制图像。

Answer 1

您正在寻找的SendInput Win32 API调用。

Answer 2

如果你想避免Win32 native interop，Windows Input Simulator是一个看起来很好看的管理包装器，围绕SendInput。但最新版本不支持鼠标模拟。但是，活动主干具有用于支持鼠标模拟的补丁（请参阅this讨论）。该项目使用VS2010 C＃，您可以从Subversion版本库here导出和构建自己。

如果您对Win32 native interop感兴趣，我将演示如何将SendInput API与F＃结合使用。这个应用程序模拟一个右键单击。

open System 
open System.Runtime.InteropServices 

type MOUSEINPUT = struct 
    val dx:int 
    val dy:int 
    val mouseData:int 
    val dwFlags:int 
    val time:int 
    val dwExtraInfo:int 
    new(_dx, _dy, _mouseData, _dwFlags, _time, _dwExtraInfo) = {dx=_dx; dy=_dy; mouseData=_mouseData; dwFlags=_dwFlags; time=_time; dwExtraInfo=_dwExtraInfo} 
end 

type INPUT = struct 
    //need to escape traditional INPUT identifier here since "type" is a reserved word 
    //though could use any other identifier name if so desired 
    val ``type``:int //0 is mouse 
    val mi:MOUSEINPUT 
    new(_type, _mi) = {``type``=_type; mi=_mi} 
end 

let MOUSEEVENTF_RIGHTDOWN = 0x0008 
let MOUSEEVENTF_RIGHTUP = 0x0010 

[<DllImport("user32.dll", SetLastError=true)>] 
extern uint32 SendInput(uint32 nInputs, INPUT* pInputs, int cbSize) 

let mutable inputRightDown = INPUT(0, MOUSEINPUT(0, 0, 0, MOUSEEVENTF_RIGHTDOWN, 0, 0)) 
let mutable inputRightUp = INPUT(0, MOUSEINPUT(0, 0, 0, MOUSEEVENTF_RIGHTUP, 0, 0)) 

SendInput(uint32 1, &&inputRightDown, Marshal.SizeOf(inputRightDown)) 
SendInput(uint32 1, &&inputRightUp, Marshal.SizeOf(inputRightUp)) 

对您的问题进行二读，我看到最终要模拟鼠标和键盘事件发送到在后台运行的应用程序，在这种情况下SendMessage/PostMessage可能是更合适的API。这仍然需要本地互操作，并希望我的示例使用SendInput将有所帮助。 Here是一个相关的问题。

Answer 3

open System.Runtime.InteropServices 

module InteropWithNative = 
    [<DllImport("user32.dll", CharSet = CharSet.Auto, CallingConvention = CallingConvention.StdCall)>] 
    extern void mouse_event(System.Int64, System.Int64, System.Int64, System.Int64, System.Int64) 

    let MOUSEEVENTF_LEFTDOWN = 0x02L 
    let MOUSEEVENTF_LEFTUP  = 0x04L 
    let MOUSEEVENTF_RIGHTDOWN = 0x08L 
    let MOUSEEVENTF_RIGHTUP  = 0x10L 

    let MouseLeftClick() = 
     mouse_event(MOUSEEVENTF_LEFTDOWN, 0L, 0L, 0L, 0L) 
     mouse_event(MOUSEEVENTF_LEFTUP, 0L, 0L, 0L, 0L) 

然后使用：

InteropWithNative.MouseLeftClick()