垂直对齐浮点数在小数点

Question

有没有简单的方法来在浮点数列上对齐小数点？换句话说，我想像的一个输出端（垂直条“|”是存在仅仅是为了清楚的目的）

(format t "~{|~16,5f|~%~}" '(798573.467 434.543543 2.435 34443.5)) 

是

| 798573.44000| 
|  434.54355| 
|   2.43500| 
|  34443.50000| 

但与结尾间隔的代替零，如下：

| 798573.44 | 
|  434.54355| 
|   2.435 | 
|  34443.5 | 

Answer 1

我不认为这可以很容易地format的内置控制字符来完成，但你可以通过自己的函数吧：

(defun my-f (stream arg colon at &rest args) 
    (declare (ignore colon at)) 
    (destructuring-bind (width digits &optional (pad #\Space)) args 
    (let* ((string (format nil "~v,vf" width digits arg)) 
      (non-zero (position #\0 string :test #'char/= :from-end t)) 
      (dot (position #\. string :test #'char= :from-end t)) 
      (zeroes (- (length string) non-zero (if (= non-zero dot) 2 1))) 
      (string (nsubstitute pad #\0 string :from-end t :count zeroes))) 
     (write-string string stream)))) 

可以使用这样的：

CL-USER> (format t "~{|~16,5/my-f/|~%~}" '(798573.467 434.543543 2.435 34443.5 10)) 
| 798573.44 | 
|  434.54355| 
|   2.435 | 
|  34443.5 | 
|  10.0 | 
NIL 

填充字符默认为#\Space，并且可以作为第三个参数是这样的："~16,5,' /my-f/"。

另一个实现使用loop：

(defun my-f (stream arg colon at &rest args) 
    (declare (ignore colon at)) 
    (loop with string = (format nil "~v,vf" (car args) (cadr args) arg) 
     and seen-non-zero = nil 
     for i from (1- (length string)) downto 0 
     as char = (char string i) 
     if (char/= char #\0) do (setq seen-non-zero t) 
     collect (if (and (not seen-non-zero) 
         (char= char #\0) 
         (not (char= #\. (char string (1- i))))) 
        (or (caddr args) #\Space) 
        char) into chars 
     finally (write-string (nreverse (coerce chars 'string)) stream))) 

（免责声明：也许我忽略了一些的format的文档更容易。）