输入框问题

Question

我目前正在使用MS Access VBA中的InputBoxes。我正在检查验证并处理用户如何通过按下“确定”或“取消”按钮与InputBox交互。

纠正我，如果我错了，但InputBoxes可以返回任何数据类型，默认返回一个字符串？例如：

Dim userInputValue As String 

'Text to display, Title, Default Value 
userInputValue = InputBox("Please enter a #", "Determine Limit", 10000) 

If userInputValue = "" Then 
    MsgBox ("You pressed the cancel button...") 
End If 

如果用户按下“取消”按钮，它将正常运行。

但是，当我换这一个整数值，像这样：

Dim userInputValue As Integer 
'Text to display, Title, Default Value 
userInputValue = InputBox("Please enter a #", "Determine Limit", 10000) 

If userInputValue = 0 Then 
    MsgBox ("You pressed the cancel button...") 
End If 

我收到Type Mismatch: Runtime Error '13'这是为什么？当我调试代码并查看返回的内容时，我发现userInputValue实际上是0，这正是我正在检查的内容。那么InputBox实际上返回一个字符串的问题呢？

Answer 1

有疑问时，请检查内置VBA帮助;）

InputBox()返回一个字符串

你可以试试这个为整数无论

Sub Sample() 
    Dim Ret As String, userInputValue As Integer 

    'Text to display, Title, Default Value 
    Ret = InputBox("Please enter a #", "Determine Limit", 10000) 

    If Ret = "" Then 
     MsgBox ("You pressed the cancel button... or you pressed OK without entering anything") 
    Else 
     If IsNumeric(Ret) Then 
      userInputValue = Val(Ret) 
     Else 
      MsgBox ("Incorrect Value") 
     End If 
    End If 
End Sub 

Answer 2

InputBox返回用户数的串进入。如果他们点击取消，它将返回一个空字符串。

在即时窗口中尝试此操作。

? TypeName(InputBox("Please enter a #", "Determine Limit", 10000)) 
String 

对于在代码测试，检查userInputValue的数值相当于是否等于零。

If Val(userInputValue) = 0 Then 
    MsgBox ("You pressed the cancel button...") 
End If 

注比InputBox不允许你区分用户是否点击取消或删除初始值（10000），并点击OK。无论哪种方式，InputBox都会返回一个空字符串（“”）。而且Val("")也返回零。如果这将是一个问题，请使用自定义表单来收集用户输入...，但不限于InputBox。

Answer 3

这里有一种方法可以捕捉与对话交互的大部分结果;

Dim value As String 
value = InputBox("Please enter a #", "Determine Limit", 10000) 

If (StrPtr(value) = 0) Then 
    MsgBox "You pressed cancel or [X]" 

ElseIf (value = "") Then 
    MsgBox "You did not enter anything" 

ElseIf (Val(value) = 0 And value <> "0") Then 
    MsgBox "Invalid number" 

Else 
    MsgBox "You entered " & value 

End If 

Answer 4

注意：以下内容仅适用于Excel。该Application.InputBox功能不可用在Access：

Application.InputBox回报“假”如果用户单击取消。

Dim userInputString As String 
Dim userInputValue As Integer 
'Text to display, Title, Default Value 
userInputString = Application.InputBox("Please enter a #", "Determine Limit", 10000) 
If userInputString = "False" Then 
    MsgBox ("You pressed the cancel button...") 
Else 
    userInputValue = CInt(Trim(userInputString)) 
End If