可以使用静态方法实现接口吗？

Question

下面的代码不能编译，但是有可能吗？

IDefaultHelp = interface 
    ['{6997FC42-7481-4CDA-940A-0351071266C7}'] 
    function GetTemplate: TXMLDocument; 

    end; 

    TDefaultHelp = class(TInterfacedObject, INodeHelp) 
    class function GetTemplate: TXMLDocument; static; <<-- error 
    end; 

我不想实例化实现对象。

有没有一种方法来实现接口，而不必Create一个实际的类？

Answer 1

我必须承认，我真的没有看到需要避免实例化一个实例。现在，您不能使用静态类方法来实现接口。如果您愿意，您可以通过委派静态类方法来实现一个接口。

我不想实例化实现对象。

所以，把你的问题，以实现接口，而无需实例化对象的愿望，你可以用一个恒定的虚函数表，从Generics.Defaults单元的比较器接口的方式实现。

例如：

unit Unit1; 

interface 

uses 
    Xml.XMLDoc; 

type 
    IDefaultHelp = interface 
    ['{6997FC42-7481-4CDA-940A-0351071266C7}'] 
    function GetTemplate: IXMLDocument; 
    end; 

function GetDefaultHelp: IDefaultHelp; 

implementation 

function NopAddref(inst: Pointer): Integer; stdcall; 
begin 
    Result := -1; 
end; 

function NopRelease(inst: Pointer): Integer; stdcall; 
begin 
    Result := -1; 
end; 

function NopQueryInterface(inst: Pointer; const IID: TGUID; out Obj): HResult; 
    stdcall; 
begin 
    Result := E_NOINTERFACE; 
end; 

function GetTemplate(inst: Pointer): IXMLDocument; 
begin 
    Result := TXMLDocument.Create(nil); 
end; 

const 
    DefaultHelp_Vtable: array[0..3] of Pointer = 
    (
    @NopQueryInterface, 
    @NopAddref, 
    @NopRelease, 
    @GetTemplate 
); 
    DefaultHelp_Instance: Pointer = @DefaultHelp_Vtable; 

function GetDefaultHelp: IDefaultHelp; 
begin 
    Result := IDefaultHelp(@DefaultHelp_Instance); 
end; 

end.