删除一行，如果重复，然后在另一列上过滤

Question

我正在过滤一个表加载赛马信息。我已经完成了8个过滤器中的7个，但是我正在为最后一个过滤器而挣扎。基本上全部我需要的是看比赛时间栏（col B），如果有2次相同的话显然在比赛中有2个选择。我只想要一个选择，所以接下来我想删除/筛选基于C列的培训师胜利％。无论哪一个更大的百分比是我需要保留的百分比。如果他们是相同的，也许把msgbox说出来，否则我可能不得不过滤第三个字段。我发现了一段越来越近的代码。

Sub text()  
Dim j As Integer, k As Integer, r As Range  
j = Range("E2").End(xlDown).Row  
For k = j To 2 Step -1  
    MsgBox k  
    Set r = Range(Cells(k, "E"), Cells(k, "E").End(xlUp))  
    If WorksheetFunction.CountIf(r, Cells(k, "E")) > 1 Then  
     Cells(k, "E").EntireRow. Delete  
    End If  
Next k  
End Sub 

Answer 1

排序教练赢得比例（降序）的数据，然后在时间上使用Range.RemoveDuplicates method。

Sub tract() 
    With Worksheets("Sheet6") '<~~ you should know which worksheet you are on 
     With .Cells(1, 1).CurrentRegion 
      'sort on the trainer win percentage (descending) 
      .Cells.Sort Key1:=.Columns(3), Order1:=xlDescending, _ 
         Orientation:=xlTopToBottom, Header:=xlYes 
      'remove duplicate times - the lower rows will be deleted 
      .RemoveDuplicates Columns:=2, Header:=xlYes 
     End With 
    End With 
End Sub 

删除重复始终去除下进入;保持入口接近顶部。这就是为什么排序培训师首先赢得百分比很重要。这不包括胜利百分比也是重复的情况。在这种情况下，必须添加另一个排序键。如果Z列是决定性因素，并且您希望保留较低的值，那么它将类似于以下内容。

Sub tract() 
    With Worksheets("Sheet6") '<~~ you should know which worksheet you are on 
     With .Cells(1, 1).CurrentRegion 
      'sort on the trainer win percentage (descending) and columns Z (ascending) 
      .Cells.Sort Key1:=.Columns(3), Order1:=xlDescending, _ 
         Key2:=.Columns(26), Order2:=xlAscending, _ 
         Orientation:=xlTopToBottom, Header:=xlYes 
      'remove duplicate times - the lower rows will be deleted 
      .RemoveDuplicates Columns:=2, Header:=xlYes 
     End With 
    End With 
End Sub