Excel 2010+ VBA - 如何搜索范围的公式而不是值

Question

我需要使用Excel VBA搜索一系列单元格，返回第一个匹配的行号。只要我正在搜索值，使用Match函数将很容易。但是我需要搜索公式，而不是价值。

例如：I需要VBA返回 “4” 当我搜索 “= A4 + 2” ...

Answer 1

，你可以直接与match

Application.Match("=A4+2", Range("B1:B5").Formula) 

这样做会给你4

编辑

你可能会得到CUS 255个字符立的错误mit来自Match。您也可以使用工作表内的输出。简单地把这个代码放在模块中：

Public Function MATCHFUNC(str As String, rng As Range, Optional fOnly As Boolean, Optional fAdr As Boolean) As Variant 
    Dim i As Long, runner As Variant 
    If UBound(rng.Value, 1) > 1 And UBound(rng.Value, 2) > 1 And Not fAdr Then MATCHFUNC = 0: Exit Function 
    For Each runner In rng 
    i = i + 1 
    If Not fOnly Or (runner.Text <> runner.Formula) Then 
     If InStr(1, runner.Formula, str, 1) Then 
     If fAdr Then MATCHFUNC = runner.Address Else MATCHFUNC = i 
     Exit Function 
     End If 
    End If 
    Next 
    MATCHFUNC = 0 
End Function 

你现在可以像使用普通的工作表一样使用它。作为例子与您的图片：
MATCHFUNC([string to search for],[range to look in],[1 to look only in cells containing formulas],[1 to get the address in $A$1 format])

=MATCHFUNC("+2",B3:B5)  = 1  - it was found in the first cell 
=MATCHFUNC("2",B1:B5)  = 2  - "2" is also in B2 
=MATCHFUNC("2",B1:B5,1) = 3  - B2 will be skipped - formulas only 
=MATCHFUNC("+2",B3:B5,,1) = "$B$3" - address of the first cell with match 
=MATCHFUNC("9",B1:B5)  = 0  - not found in range 
=MATCHFUNC("2",A1:B5)  = 0  - range needs to be only 1 row or 1 column without fAdr 
=MATCHFUNC("2",A1:B5,,1) = "$B$2" - check goes A1->B1...->A2->B2... 

您可能需要使用fAdr = 1特殊情况类似：

=ROW(INDIRECT(MATCHFUNC("2",B4:B5,,1))) = 4 - absolute row of the first cell with match 

Asuming你不想检查B1：无论出于何种原因B3但你需要绝对的行。

不过你也可以在VBA本身使用它像：iVal = MATCHFUNC("=B", Range("B4:B5"))
同样的功能本身可以easiely改善，也输出数组或一个运行检查不同的字符串或做任何你想要的（如果没有必要，你也可以跳过2个选项部分，以保持它的速度和易于理解）:)

Answer 2

如果你想要第一个找到的单元格的地址 - 这将作为工作表函数（=FindFirst("=A",B2:B6)），并从另一个VBA程序：

Public Function FindFirst(FindValue As String, InRange As Range) As Variant 

    Dim rFound As Range 

    With InRange 

     Set rFound = .Find(_ 
      What:=FindValue, _ 
      After:=InRange.Cells(InRange.Cells.Count), _ 
      LookIn:=xlFormulas, _ 
      LookAt:=xlPart) 

     If Not rFound Is Nothing Then 
      FindFirst = rFound.Address 
     Else 
      FindFirst = CVErr(xlErrValue) 
     End If 

    End With 

End Function 

另一方面，如果你想要所有找到的单元格，你可以使用它 - 但是请注意，它不能用作工作表函数。

Public Sub Test() 

    MsgBox FindInFormula("=A", ThisWorkbook.Worksheets("Sheet1").Range("B2:B6")).Address 

End Sub 

Public Function FindInFormula(FindValue As String, InRange As Range) As Range 

    Dim rFound As Range 
    Dim sFirstAdd As String 
    Dim rReturnRange As Range 

    With InRange 

     Set rFound = .Find(_ 
      What:=FindValue, _ 
      After:=InRange.Cells(InRange.Cells.Count), _ 
      LookIn:=xlFormulas, _ 
      LookAt:=xlPart) 

     If Not rFound Is Nothing Then 
      sFirstAdd = rFound.Address 
      Do 
       If rReturnRange Is Nothing Then 
        Set rReturnRange = rFound 
       Else 
        Set rReturnRange = Union(rReturnRange, rFound) 
       End If 
       Set rFound = .FindNext(rFound) 
      Loop While Not rFound Is Nothing And rFound.Address <> sFirstAdd 
     End If 

    End With 

    Set FindInFormula = rReturnRange 

End Function 

您将需要更新的程序返回地址或到单元格的引用 - 调整您的需求。