如何在Excel VBA中的某个字段下直接添加值？

Question

我有这个代码，但我想直接在excel中的“名称”下添加名称等，但是至今它只添加它在第1行。有人可以帮我吗？

例如，当我输入名称框时，无论“我的名字”在我的Excal表单中的哪个位置，我都希望该值直接在Excel中的“Name”下。

我是新来的，这是我的第一个问题:)

'find first empty row in database 
iRow = ws.Cells.Find(What:="Name", SearchOrder:=xlRows, _ 
    SearchDirection:=xlPrevious, LookIn:=xlValues).Row + 1 
'check for a part number 
If Trim(Me.TxtName.Value) = "" Then 
    Me.TxtName.SetFocus 
    MsgBox "Please enter a part number" 
    Exit Sub 
End If 

'copy the data to the database 
'use protect and unprotect lines, 
'  with your password 
'  if worksheet is protected 
With ws 
' .Unprotect Password:="password" 
    .Cells(iRow, 1).Value = Me.TxtName.Value 
    .Cells(iRow, 2).Value = Me.TxtLocation.Value 
    .Cells(iRow, 3).Value = Me.TxtDate.Value 
    .Cells(iRow, 4).Value = Me.TxtQuantity.Value 
' .Protect Password:="password" 
End With 

• 感谢。

Answer 1

请尝试使用下面的代码来代替您发布的代码部分。

Dim anchorCell As Range 

'find first empty row in database 
If ws.Cells(1,1).Value = "Name" Then 
    Set anchorCell = ws.Cells(1,1) 
Else 
    Set anchorCell = ws.Cells.Find(What:="Name", SearchOrder:=xlRows, _ 
     SearchDirection:=xlNext, LookIn:=xlValues) 
End If 

If Not anchorCell Is Nothing Then 
    'check for a part number 
    If Trim(Me.TxtName.Value) = "" Then 
     Me.TxtName.SetFocus 
     MsgBox "Please enter a part number" 
     Exit Sub 
    End If 
    'copy the data to the database 
    'use protect and unprotect lines, 
    '  with your password 
    '  if worksheet is protected 
    With anchorCell 
    ' .Unprotect Password:="password" 
     .Offset(1, 0).Value = Me.TxtName.Value 
     .Offset(1, 1).Value = Me.TxtLocation.Value 
     .Offset(1, 2).Value = Me.TxtDate.Value 
     .Offset(1, 3).Value = Me.TxtQuantity.Value 
    ' .Protect Password:="password" 
    End With 
End If 

Answer 2

假设OP真的要填充第一个空行：

Dim pNum, rngName As Range 

pNum = Trim(Me.TxtName.Value) 'check for a part number 

If Len(pNum) = 0 Then 
    Me.TxtName.SetFocus 
    MsgBox "Please enter a part number" 
    Exit Sub 
End If 

'find first empty row in database 
Set rngName = ws.Cells.Find(What:="Name", SearchOrder:=xlRows, _ 
    SearchDirection:=xlPrevious, LookIn:=xlValues, LookAt:=xlWhole) 

If Not rngName is Nothing then 
    With ws.cells(rows.count, rngName.Column).End(xlUp).offset(1,0).entirerow 
     .Cells(1).Value = pNum 
     .Cells(2).Value = Me.TxtLocation.Value 
     .Cells(3).Value = Me.TxtDate.Value 
     .Cells(4).Value = Me.TxtQuantity.Value 
    End With 
Else 
    msgbox "'Name' header not found!" 
End if