只能发出一些HTML当一个变量在XSLT

Question

使用XSLT我试图找出一个办法只能发出HTML表行，当值来自于该换每次最后一次迭代不同，上一次迭代不同循环。基本上，我想让表格看起来具有分组标题，只需在标题更改后写出它。我有一点麻烦

概念上工作了我怎么能做到这一点考虑一旦它被定义，你不能改变一个变量的值。

<xsl:for-each select="//databaseConstraint/constraint"> 

    <xsl:variable name="caption" select="@caption" /> 

    <tr> 
     <th colspan="2"><xsl:value-of select="$caption" /></th> 
    </tr> 

    ... 

</xsl:for-each > 

更新我下面试过，但我得到一个错误：NodeTest这里

<xsl:for-each select="//databaseConstraint/constraint"> 

    <xsl:variable name="caption" select="@caption" /> 

    <xsl:if test="not(@caption = preceding-sibling::@caption)"> 
    <tr> 
     <th colspan="2"> 
      <xsl:value-of select="$caption" /> 
     </th> 
    </tr> 
    </xsl:if> 

    ... 

</xsl:for-each > 

Answer 1

<xsl:if test="not(@caption = preceding-sibling::@caption)"> 

这将测试字幕是否等于一个字幕属性即上下文节点的兄弟，即你正在处理所述约束元件的兄弟节点。但我怀疑它“失败”，因为语法错误，因为标题步骤有两个轴：preceding-sibling::和attribute::（这是@的缩写）。

你可能想要的是

<xsl:if test="not(@caption = preceding-sibling::constraint[1]/@caption)"> 

这将做你想做的，它比Muenchian简单，它可能快速就够了，如果浏览器的XPath实现是体面的，因为它只需要测试一个其他节点，而不是所有先前的约束节点。

如果这种策略对于您的目的不够快，如果你有很多数据，你可以使用Muenchian分组，就像@Frédéric说的那样。

此外：[1]是[position() = 1]的缩写。这里的意思是，在=的右侧，我们只有在当前元素之前的约束。如果我们省略了[1]，我们将比较当前元素的@caption值和前面的兄弟约束元素中的全部的@captions。

它认识到XPath的=运营商（有机会时）在节点集工作，而不只是单值或节点是非常重要的。所以A = B，其中A和B是节点集，如果有节点集A的任何成员等于节点集B的任何成员，则返回true。这更像是SQL中的连接。这是一个强大的操作，但你必须知道它在做什么。

另一个细节...为什么[1]产生紧接在之前的约束元素而不是文档中的第一个？因为position()反映当前轴的方向，在本例中为preceding-sibling。如XPath spec所述，

An axis that only ever contains the context node or nodes that are before the context node in document order is a reverse axis. Thus, the ancestor, ancestor-or-self, preceding, and preceding-sibling axes are reverse axes; all other axes are forward axes. ...

The proximity position of a member of a node-set with respect to an axis is defined to be the position of the node in the node-set ordered in document order if the axis is a forward axis and ordered in reverse document order if the axis is a reverse axis. The first position is 1.

HTH。

Answer 2

预计这并不容易使用XSLT 1.0做。如果您的实现支持XSLT 2.0功能，请使用xsl:for-each-group。如果您遇到1.0，请查看this Muenchian implementation using keys。

Answer 3

您可以尝试比较使用前或兄弟姐妹先行当前节点（或它的属性之一）与之前的节点，并只显示，如果目前的！=前面的桌子上。请参阅XPath Axes。

Answer 4

I'm trying to work out a way to only emit a HTML table row when a value is different from the last iteration of the for-each loop

这个答案字面上。如果你想执行分组了解Muenchian grouping。

这种转变：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 

<xsl:template match="/"> 
    <xsl:variable name="vConstraints" 
     select="//databaseConstraint/constraint"/> 
    <table> 
     <xsl:for-each select="$vConstraints"> 
     <xsl:variable name="vCaption" select="@caption" /> 
     <xsl:variable name="vPos" select="position()"/> 

     <xsl:if test="not($vCaption = $vConstraints[$vPos -1]/@caption)"> 
      <tr> 
       <th colspan="2"><xsl:value-of select="$vCaption" /></th> 
      </tr> 
     </xsl:if> 
     </xsl:for-each> 
    </table> 
</xsl:template> 
</xsl:stylesheet> 

当下面的XML文档应用：

<t> 
<a> 
<databaseConstraint> 
    <constraint caption="Simple Constraint"/> 
</databaseConstraint> 
<databaseConstraint> 
    <constraint caption="Simple Constraint"/> 
</databaseConstraint> 
</a> 
<b> 
<databaseConstraint> 
    <constraint caption="Complex Constraint"/> 
</databaseConstraint> 
</b> 
</t> 

产生想要的，正确的结果：

<table> 
    <tr> 
     <th colspan="2">Simple Constraint</th> 
    </tr> 
    <tr> 
     <th colspan="2">Complex Constraint</th> 
    </tr> 
</table> 

请注意：

1. 改造工程，即使在情况下，当<constraint>元素不是同级，或者即使他们中的一些祖先/彼此的后代。

2. 在这种情况下，有必要收集所有<constraint>元件在一个变量中，并rememper当前<constraint>元件的position()，使得有可能将其与<constraint>元件在先前位置比较节点集。