用XSLT转换GML

Question

我想弄清楚这段代码有什么问题，但是4小时后我放弃了！我在这里尝试了很多不同的解决方案，从web，bot都无法工作。

我想要做的是将“gml：coordinates”值放到“point”属性中。我想这与名字空间有关。还是其他什么东西......

XML文件：

<?xml version="1.0" encoding="ISO-8859-1"?> 
<gml:LineString> 
    <gml:coordinates>-7 -7 0 7 -7 0 7 7 0 -7 7 0</gml:coordinates> 
</gml:LineString> 

XSL文件：

<?xml version="1.0" encoding="ISO-8859-1"?> 
<xsl:stylesheet version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:gml="http://www.opengis.net/gml"> 

<xsl:template match="/gml:LineString"> 
    <Transform> 
     <Shape> 
      <IndexedFaceSet> 
       <xsl:attribute name="coordIndex"> 
        <xsl:text>0 1 2 3 -1</xsl:text> 
       </xsl:attribute> 

       <Coordinate> 
        <xsl:attribute name="point"> 
         <xsl:text> 
          <xsl:value-of select="/gml:coordinates" /> 
         </xsl:text> 
        </xsl:attribute> 
       </Coordinate> 
      </IndexedFaceSet> 
     </Shape> 
    </Transform> 
</xsl:template> 
</xsl:stylesheet> 

而阿贾克斯脚本（返回正确的结果，如果属性被设置为“-7 -7 0 7 -7 0 7 7 0 -7 7 0“insted of”/ gml：coordinates“）：

var xml = document.implementation.createDocument("", "", null); 
var xsl = document.implementation.createDocument("", "", null); 
xml.async = false; 
xsl.async = false; 
xml.load("xsl/ajax.xml"); 
xsl.load("xsl/ajax.xsl"); 
var processor = new XSLTProcessor(); 
processor.importStylesheet(xsl); 
var output = processor.transformToFragment(xml, document); 
document.getElementById("scene").appendChild(output); 

在此先感谢。

Answer 1

只需更换：

<Coordinate> 
    <xsl:attribute name="point"> 
    <xsl:text> 
     <xsl:value-of select="/gml:coordinates" /> 
    </xsl:text> 
    </xsl:attribute> 
</Coordinate> 

与：

<Coordinate> 
    <xsl:attribute name="point"> 
     <xsl:value-of select="gml:coordinates" /> 
    </xsl:attribute> 
</Coordinate> 

说明：至少有两个问题在这里：

1. <xsl:text>不能在其内部包含其他xsl元素 - 只有文本。

2. XPath表达式/gml:coordinates未选择任何内容，因为源XML文档中没有/gml:coordinates top元素。

此外重构：该代码可以通过使用*来进一步简化AVT * S（属性 - 值模板）：

替换：

<Coordinate> 
    <xsl:attribute name="point"> 
     <xsl:value-of select="gml:coordinates" /> 
    </xsl:attribute> 
</Coordinate> 

与：

<Coordinate point="{gml:coordinates}"/> 

更换：

<IndexedFaceSet> 
    <xsl:attribute name="coordIndex"> 
    <xsl:text>0 1 2 3 -1</xsl:text> 
    </xsl:attribute> 

与：

<IndexedFaceSet coordIndex="0 1 2 3 -1"> 

完整代码的修正和重构后：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
xmlns:gml="http://www.opengis.net/gml"> 
    <xsl:template match="/gml:LineString"> 
     <Transform> 
      <Shape> 
       <IndexedFaceSet coordIndex="0 1 2 3 -1"> 
        <Coordinate point="{gml:coordinates}"/> 
       </IndexedFaceSet> 
      </Shape> 
     </Transform> 
    </xsl:template> 
</xsl:stylesheet> 

，其结果是：

<Transform xmlns:gml="http://www.opengis.net/gml"> 
    <Shape> 
     <IndexedFaceSet coordIndex="0 1 2 3 -1"> 
      <Coordinate point="-7 -7 0 7 -7 0 7 7 0 -7 7 0"/> 
     </IndexedFaceSet> 
    </Shape> 
</Transform>