如何在Delphi XE中将背景图像设置为TListview？

Question

我怎么能在Delphi XE中将背景图像设置为TListview？

我想制作一个应用程序，如Windows资源管理器。

Answer 1

为了在列表视图中设置水印，您需要使用LVM_SETBKIMAGE消息，并且需要重写TListView的默认WM_ERASEBKGND消息。列表视图获取位图句柄的所有权，因此您需要使用TBitmap的ReleaseHandle，而不仅仅是Handle。

如果您希望它与左上角对齐，而不是像Explorer那样右下角，请使用LVBKIF_SOURCE_HBITMAP而不是LVBKIF_TYPE_WATERMARK作为ulFlags值。

uses 
    CommCtrl, ...; 

type 
    TListView = class(ComCtrls.TListView) 
    protected 
    procedure WndProc(var Message: TMessage); 
     override; 
    end; 

    TForm4 = class(TForm) 
    ListView1: TListView; 
    procedure FormCreate(Sender: TObject); 
    end; 

procedure TListView.WndProc(var Message: TMessage); 
begin 
    if Message.Msg = WM_ERASEBKGND then 
    DefaultHandler(Message) 
    else 
    inherited WndProc(Message); 
end; 

procedure TForm4.FormCreate(Sender: TObject); 
var 
    Img: TImage; 
    BkImg: TLVBKImage; 
begin 
    FillChar(BkImg, SizeOf(BkImg), 0); 
    BkImg.ulFlags := LVBKIF_TYPE_WATERMARK; 
    // Load image and take ownership of the bitmap handle 
    Img := TImage.Create(nil); 
    try 
    Img.Picture.LoadFromFile('C:\Watermark.bmp'); 
    BkImg.hbm := Img.Picture.Bitmap.ReleaseHandle; 
    finally 
    Img.Free; 
    end; 
    // Set the watermark 
    SendMessage(ListView1.Handle, LVM_SETBKIMAGE, 0, LPARAM(@BkImg)); 
end; 

拉伸水印

ListView中本身不支持在整个背景拉伸的位图。要做到这一点，你需要自己做一个StretchBlt来响应WM_ERASEBKGND。

type 
    TMyListView = class(TListView) 
    protected 
    procedure CreateHandle; override; 
    procedure CreateParams(var Params: TCreateParams); override; 
    procedure WMEraseBkgnd(var Msg: TWMEraseBkgnd); message WM_ERASEBKGND; 
    public 
    Watermark: TBitmap; 
    end; 

procedure TMyListView.CreateHandle; 
begin 
    inherited; 
    // Set text background color to transparent 
    SendMessage(Handle, LVM_SETTEXTBKCOLOR, 0, CLR_NONE); 
end; 

procedure TMyListView.CreateParams(var Params: TCreateParams); 
begin 
    inherited; 
    // Invalidate every time the listview is resized 
    Params.Style := Params.Style or CS_HREDRAW or CS_VREDRAW; 
end; 

procedure TMyListView.WMEraseBkgnd(var Msg: TWMEraseBkgnd); 
begin 
    StretchBlt(Msg.DC, 0, 0, Width, Height, Watermark.Canvas.Handle, 
    0, 0, Watermark.Width, Watermark.Height, SrcCopy); 
    Msg.Result := 1; 
end; 

Answer 2

一个Tlistview是不错，但如果你想要更多。我建议你必须更新VirtualStringTree(VirtualTreeView)非常灵活，你可以定制它几乎任何你想要的，最重要的是它的免费。