问题XSLT输出

Question

在.xml文件，我有这样的：

<function>true</function> 

在架构ILE，我已经将它定义为一个布尔值。所以现在，它工作正常。但对于XSLT文件即的.xsl，

Answer 1

您可以使用xsl:choose：

<td> 
    <xsl:choose> 
    <xsl:when test="function = 'true'">@</xsl:when> 
    <xsl:otherwise>&#32;</xsl:otherwise> 
    </xsl:choose> 
</td> 

Answer 2

这可以非常简单地完成，而不是在所有需要的条件XSLT指令，并完全在XSLT的精神（推式）：

这种转变：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:template match="node()|@*"> 
    <xsl:copy> 
     <xsl:apply-templates select="node()|@*"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="function/text()[.='true']">@</xsl:template> 
<xsl:template match="function/text()[not(.='true')]"> 
    <xsl:text> </xsl:text> 
</xsl:template> 

<xsl:template match="function"> 
    <td><xsl:apply-templates/></td> 
</xsl:template> 
</xsl:stylesheet> 

当在下面的XML文档施加：

<function>true</function> 

产生想要的，正确的结果：

<td>@</td> 

当在下面的XML文档被施加相同的变换：

<function>false</function> 

再次正确的，希望的结果是产生：

<td> </td> 

最后，使用黑客（在XSLT 2.0/XPath 2.0中这不是必要的），我们可以只使用一个模板：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:template match="node()|@*"> 
    <xsl:copy> 
     <xsl:apply-templates select="node()|@*"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="function"> 
    <td> 
    <xsl:value-of select= 
    "concat(substring('@', 1 div (.='true')), 
      substring(' ', 1 div not(.='true')) 
     ) 
    "/> 
    </td> 
</xsl:template> 
</xsl:stylesheet>