AutoHotkey的 - 热键组合输入 - 暂停一个按键 - 通电路关键

Question

如何：

1. 读（等待和记录），只需按一下（即按住Shift键的Alt-F5）
2. 通过这记录关键组合到程序（即Photoshop），没有它作为热键运行。

我试过这个，但它不适用于我的非ASCII热键。它适用于热键。

F6:: 
Suspend, On 
Input, OutputVar, L1 M 
Send, %OutputVar% 
Suspend, Off 
return 


F5::Run explorer 
t::Run notepad 
!+5::Run cmd 

• F5是运行程序浏览器热键。
• F6是一个热键，可暂停一次按下所有热键。并通过组合键作为非热键
• 当我在Firefox中时，如果按F6 F5，它将进入firefox的刷新页面动作。
• 当我按下F5，没有前面的F6，它会打开资源管理器

Answer 1

两个解决方案。

1. 要捕捉热键添加到您的输入是这样的：

   Input, OutputVar, L1, {LControl}{RControl}{LAlt}{RAlt}{LShift}{RShift}{LWin}{RWin}{AppsKey}{F1}{F2}{F3}{F4}{F5}{F6}{F7}{F8}{F9}{F10}{F11}{F12}{Left}{Right}{Up}{Down}{Home}{End}{PgUp}{PgDn}{Del}{Ins}{BS}{Capslock}{Numlock}{PrintScreen}{Pause} 
   

否则这些非ASCII键由输入忽略。

或者，使F5键应用程序的行为特定。

SetTitleMatchMode, 2 
#IfWinNotActive, Firefox 
    F5::Run explorer 
#IfWinNotActive 

这样，你的F5键总是启动IE浏览器，当你的Firefox除了工作，然后F5将F5并重新加载页面。

Answer 2

根据你的笔记，我认为你想要做到以下几点。 使用#r阻止任何输入并启动您的脚本，然后当您再次按#r时，脚本停止并且输入被恢复。如果是这种情况，你可以试试这个：

#Singleinstance force 
$#r:: 
If (MyToggle := !MyToggle) ; Toggle the value MyToggle True/False 
    { 
     ToolTip,Input blocked [Win]+r,A_ScreenWidth/2-50,0 
     BlockInput, on ; In Vista and above, you need to run AHK as admin or run AHK in compatility mode with Windows XP SP 3 
     SetTimer RunMyScript, 500 ; Start the actual script in 500 ms outside of this script, so you can toggle 
     Return 
    } 
Else 
    { 
     Tooltip 
     BlockInput, off 
     ;Reload ; This will KILL the "RunMyScript" IMMEDIATELY at an unpredictable location. 
     Return 
    } 
return 

RunMyScript: ; This script runs independently from the script above. The script stops after 10 loops and resets the input. [Ctrl]+[Alt]+[Del] still kills any script. 
SetTimer RunMyScript, Off ; Turn the 500 ms timer off 
loop, 10 
{ 
    if (!MyToggle) ; Check the MyToggle variable to see if you need to stop the script. This will Exit the script at a predictable location. 
     Exit 

    SoundBeep, 600,600 
    Sleep, 1000 
} 
BlockInput, off ; Allow keyboard & mouse input again. Warning the [Win] key key may be left activated, causing keyboard actions to start applications 
Tooltip 
Return 

让我知道这是你在找什么。

Answer 3

通过这种方式可以将某些内容写入日志文件。在这里，我每天都创建一个新的日志文件，并且每次输入都必须重复最后两行（以获取实际时间）。

FormatTime, DateRef, %TimeNow%, yyyyMMdd ; Store current date in variable DateRef 
MyLogFile = %A_ScriptDir%\LogFiles\LogFile-%DateRef%.txt ; Define the name of the log file. 
FormatTime, TimeAbsolute, %TimeNow%, HH:mm:ss ; Use the current time to set the timestamp variable called TimeAbsolute used inside the Log File 
FileAppend, `n`r| %TimeAbsolute% | Your hotkey and possibly in which application`n`r,%MyLogFile% ; Write logfile 

Answer 4

我还没有检查这一点，但我认为这是你在找什么...

FormatTime, DateRef, %TimeNow%, yyyyMMdd ; Store current date in variable DateRef 
MyLogFile = %A_ScriptDir%\LogFiles\LogFile-%DateRef%.txt ; Define the name of the log file. 
FileAppend, `n`r| %TimeAbsolute% | Your hotkey and possibly in which application`n`r,%MyLogFile% ; Write logfile 
Suspend, on ; Start with hotkeys disabled 
Return 

Pause:: ; Use pause key to 'activate' the hotkeys 
Suspend, Off ; Activate the hotkeys 
SetTimer, Stop, 10000 ; If no hotkey is pressed within 10 seconds, deactivate the hotkeys aagain 
Return 

Stop: ; Deactivate the hotkeys 
Suspend, on ; Deactivate the hotkeys 
SetTimer, Stop, Off ; turn the stop timer off 
Return 

q:: ; use a key (q) as a hotkey 
Soundbeep, 600,600 ; sound a short beep to show that it works 
HotKeyType = "q key" 
WinGet, ApplicationType, ProcessName, A 
GoSub, Write 
Return 

Write: 
SetTimer, Stop, Off ; Make sure that the stop timer is turned off 
FormatTime, TimeAbsolute, %TimeNow%, HH:mm:ss ; Use the current time to set the timestamp variable called TimeAbsolute used inside the Log File 
FileAppend, `n`r| %TimeAbsolute% | %HotKeyType% used in %ApplicationType%`n`r,%MyLogFile% ; Write logfile 
Suspend, On ; Disable the hotkeys again 
Exit 

Answer 5

对于登录的钥匙，我专门定义的要打印的关键字类型将日志文件作为文本字符串，这样您就可以为每个不可打印的键定义自己的文本。

我按照以下方式重新编写了脚本： 当您按F6一次，然后按另一个键（在此情况下为F5）时，它将执行哔声（充当热键）。如果按F6两次，如果将发送F6，就好像没有设置热键一样。如果在没有先按F6的情况下按下F5键，则只会发送F5，就好像热键没有激活一样。希望这是你想要的东西....

$F6:: 
If (MySuspend := !MySuspend) ; Toggle the value MySuspend True/False 
{ 
     ToolTip Hotkeys On (F6),A_ScreenWidth/2-50,0 
} 
Else 
{ 
    Tooltip 
    Send, {F6} 
} 
return 

$F5:: 
If MySuspend 
{ 
    SoundBeep, 600, 600 
    MySuspend := 0 
    ToolTip 
} 
else 
{ 
    Send, {F5} 
} 
Return 

Answer 6

好吧，我觉得这是最后的脚本....

通常所有的按键时3秒，除非您按F6的行为像往常一样，那么你可以使用热键。只要你使用热键，行为就会再次恢复正常（3秒只有在你没有按热键的情况下）。当你按两次F6时，它将发送F6。让我知道，如果你找到了一个更简单的解决方案，因为这是相当复杂的。

FormatTime, DateRef, %TimeNow%, yyyyMMdd ; Store current date in variable DateRef 
MyLogFile = %A_ScriptDir%\LogFile-%DateRef%.txt ; Define the name of the log file for today. 
FormatTime, TimeAbsolute, %TimeNow%, HH:mm:ss 
FileAppend, | %TimeAbsolute% | Your hotkey and possibly in which application`n`r,%MyLogFile% ; Write logfile 
SpecialF6:=1 
Suspend, On 
Return 

$F6:: 
Suspend, Permit 
If SpecialF6 
{ 
Suspend, Off 
ToolTip Hotkeys On for 3 seconds,A_ScreenWidth/2-50,0 
SpecialF6:=0 
SetTimer, SuspendOn, 3000 
Return 
} 
else 
{ 
    Send, {F6} 
    MyText = F6 
    Gosub, WriteClose 
} 
Return 

SuspendOn: 
Suspend, On 
SetTimer, SuspendOn, Off 
ToolTip 
SpecialF6:=1 
return 

F5:: 
Run explorer 
MyText = F5 Run Explorer 
Gosub, WriteClose 
Return 

t:: 
Run notepad 
MyText = t Run Notepad 
Gosub, WriteClose 
Return 

!+5:: 
Run cmd 
MyText = Alt Shift 5 Run Command 
Gosub, WriteClose 
return 

WriteClose: 
Suspend, On 
SetTimer, SuspendOn, Off 
FormatTime, TimeAbsolute, %TimeNow%, HH:mm:ss 
ToolTip 
SpecialF6:=1 
FileAppend, | %TimeAbsolute% | %MyText%`n`r,%MyLogFile% ; Write logfile 
Exit