FlexLM VIM语法高亮

Question

我正在尝试使vim vim语法文件突出显示FlexLM系统的文件。

它包含用空格隔开的关键字行，我想基础上，他们是在什么位置以突出的东西不同颜色

例如： FEATURE Infinisim infinism 2.4 31-MAY-2014 1个SUPERSEDE

每一行以单词FEATURE开头的单词都有一个颜色的下一个单词，另一个单词的下一个单词用空格分隔。

有没有办法做到这一点？

感谢

Answer 1

我有一个“诺迪” VIM文件作为所有我想看到的是基础知识。将下面的〜/ vim的/语法/ flexlm.vim

" For version 6.x: Quit when a syntax file was already loaded 
if version < 600 
    syntax clear 
elseif exists("b:current_syntax") 
    finish 
endif 

" Syntax is case INsensitive 
syn case ignore 


" Main statements 
"=============================================== 
syn keyword  flexlmStatement  SERVER DAEMON USE_SERVER 

syn keyword  flexlmStatement  FEATURE INCREMENT skipwhite nextgroup=flexlmToken 
syn region  flexlmToken start="\S" end="\s" skipwhite nextgroup=flexlmDaemon 
syn region  flexlmDaemon start="\S" end="\s" skipwhite nextgroup=flexlmVer 
syn region  flexlmVer start="\S" end="\s" skipwhite nextgroup=flexlmDate 
syn region  flexlmDate start="\S" end="\s" skipwhite nextgroup=flexlmCount 
syn region  flexlmCount start="\S" end="\s" skipwhite nextgroup=flexlmStuff 
syn region  flexlmStuff start="\S" end="$" 

syn region flexlmComment start=/#/ end=/$/ 

syn sync minlines=10 

if version >= 508 || !exists("did_flexlm_syntax_inits") 
    if version < 508 
    let did_flexlm_syntax_inits = 1 
    command -nargs=+ HiLink hi link <args> 
    else 
    command -nargs=+ HiLink hi def link <args> 
    endif 

    HiLink flexlmComment   Comment 
    HiLink flexlmStatement  Keyword 
    HiLink flexlmToken   Identifier 
    HiLink flexlmDaemon   Tag 
    HiLink flexlmVer    Label 
    HiLink flexlmCount   Macro 
    HiLink flexlmStuff   Type 

    delcommand HiLink 
endif 

let b:current_syntax = "flexlm" 

然后，您可以设置这是默认的语法高亮显示在你的〜/ .vimrc

au BufRead,BufNewFile *.dat set filetype=flexlm 

以下显然你可以根据你的文件扩展名来玩这条线名为.lic等，您可以键入vim的

:set syntax=flexlm 

如果你觉得扩展语法高亮以下 - 请后的结果早在这将是很好的选项包括文件等