在VB内运行基于Java控制台的程序'10

Question

我基本上试图在vb.net里面运行一个基于java控制台的程序并且显示输出让我们说一个正常的文本框并且还有另一个文本框键入程序的输入。是否有可能做到这一点？

Answer 1

你基本上需要创建一个带有参数的新进程，这个参数是你的文本框的输入。然后，你可以捕捉程序的输出，将其存储在一个变量，并显示在对话框中。

这里有一个小片断：

Dim command As String = "C:\My Dir\MyFile.exe" 
Dim args As String = "MyParam1 MyParam2" 

Dim proc = New Process() With { _ 
    Key .StartInfo = New ProcessStartInfo() With { _ 
    Key .FileName = "program.exe", _ 
    Key .Arguments = args, _ 
    Key .UseShellExecute = False, _ 
    Key .RedirectStandardOutput = True, _ 
    Key .CreateNoWindow = True _ 
    } _ 
} 

proc.Start() 

While Not proc.StandardOutput.EndOfStream 
    Dim line As String = proc.StandardOutput.ReadLine() 
    ' do something with the line 
End While 

Answer 2

下面是一些样板代码（确保有txtInput和txtOutput的形式）：

Private m_process As Process 
Private m_encoding_for_program As System.Text.Encoding 

Private Sub Form1_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load 

    m_encoding_for_program = System.Text.Encoding.GetEncoding(866) 'Adjust as needed 

    Dim psi As New ProcessStartInfo 
    psi.CreateNoWindow = True 
    psi.UseShellExecute = False 
    psi.FileName = "cmd.exe" 
    psi.RedirectStandardInput = True 
    psi.RedirectStandardError = True 
    psi.StandardErrorEncoding = m_encoding_for_program 
    psi.RedirectStandardOutput = True 
    psi.StandardOutputEncoding = m_encoding_for_program 

    m_process = Process.Start(psi) 
    AddHandler m_process.OutputDataReceived, AddressOf OutputDataReceived 
    AddHandler m_process.ErrorDataReceived, AddressOf OutputDataReceived 'Make different handler if needed. 
    m_process.BeginOutputReadLine() 
    m_process.BeginErrorReadLine() 

End Sub 

Private Sub Form1_FormClosed(ByVal sender As Object, ByVal e As System.Windows.Forms.FormClosedEventArgs) Handles Me.FormClosed 
    m_process.CancelOutputRead() 
    m_process.CancelErrorRead() 
    m_process.Kill() 
End Sub 

Private Sub TextBox1_KeyUp(ByVal sender As Object, ByVal e As System.Windows.Forms.KeyEventArgs) Handles txtInput.KeyUp 
    If e.KeyCode = Keys.Enter Then 
     Dim b = m_encoding_for_program.GetBytes(txtInput.Text) 
     m_process.StandardInput.BaseStream.Write(b, 0, b.Length) 
     m_process.StandardInput.WriteLine() 
    End If 
End Sub 

Private Sub OutputDataReceived(ByVal sender As Object, ByVal e As DataReceivedEventArgs) 
    Me.Invoke(CType(AddressOf Me.ThreadProcSetter, Action(Of Object)), e.Data) 
End Sub 

Private Sub ThreadProcSetter(ByVal text As Object) 
    txtOutput.AppendText(DirectCast(text, String) & ControlChars.NewLine) 
End Sub 

在txtInput输入命令，然后按回车看结果。确保txtOutput是多行。
添加错误需要检查。