选择范围内的形状。奇怪的看似随机的结果？

Question

我试图选择一个范围内的形状，但代码的结果并不完全符合我的预期。它随机选择比预期更多的形状（不在范围内）。

Public Sub ShapeSelection() 
Dim Sh As Shape 
Dim selectedOne As Boolean 
On Error Resume Next 

With ActiveSheet 
    For Each Sh In .Shapes 
     If Not Application.Intersect(Sh.TopLeftCell, .Range(Selection.Address)) Is Nothing Then 
      If selectedOne = False Then 
       Sh.Select 
       selectedOne = True 
      Else 
       Sh.Select (False) 
      End If 
     End If 
    Next Sh 
End With 
End Sub 

Answer 1

奇怪的行为由“Selection.Address”

在你的循环，当第一个形状被发现引起的，你从范围C3改变当前的选择，让我们说，到第一形状

下次通过循环它试图比较（相交）TopLeftCell的地址与形状对象的地址：形状对象本身没有地址（其TopLeftCell有一个）

但是你去了关于它很长的路要走：你不需要使用相交。代码波纹管工作如你所期望：

Option Explicit 

Public Sub ShapeSelection() 

    Dim Sh As Shape 
    Dim sRng As Range 

    With ActiveSheet 
     Set sRng = Selection 
     For Each Sh In .Shapes 
      If Sh.TopLeftCell.Address = sRng.Address Then 
       Sh.Select 
       Exit For 
      End If 
     Next Sh 
    End With 
End Sub 

---

编辑：我刚才注意到你前面的问题：How to select multiple shapes based on range?

交点所需要完成这一要求，但你仍然需要保留对所选单元格的引用：

Option Explicit 

Public Sub ShapeSelection() 

    Dim Sh As Shape 
    Dim sRng As Range 

    With ActiveSheet 
     If TypeName(Selection) = "Range" Then 
      Set sRng = Selection 
      If sRng.CountLarge = 1 Then 
       For Each Sh In .Shapes 
        Sh.Select False 
       Next Sh 
      Else 
       For Each Sh In .Shapes 
        If Not Application.Intersect(Sh.TopLeftCell, .Range(sRng.Address)) Is Nothing Then 
         Sh.Select False 
        End If 
       Next Sh 
      End If 
     End If 
    End With 
End Sub